pyrox.dev
1{ lib, stdenv, fetchFromGitHub, fetchpatch, cmake, boost, gtest, zlib }:
2
3stdenv.mkDerivation rec {
4 pname = "lucene++";
5 version = "3.0.8";
6
7 src = fetchFromGitHub {
8 owner = "luceneplusplus";
9 repo = "LucenePlusPlus";
10 rev = "rel_${version}";
11 sha256 = "12v7r62f7pqh5h210pb74sfx6h70lj4pgfpva8ya2d55fn0qxrr2";
12 };
13
14 nativeBuildInputs = [ cmake ];
15 buildInputs = [ boost gtest zlib ];
16
17 cmakeFlags = [ "-DCMAKE_INSTALL_LIBDIR=lib" ];
18
19 patches = [
20 (fetchpatch {
21 name = "pkgconfig_use_correct_LIBDIR_for_destination_library";
22 url = "https://github.com/luceneplusplus/LucenePlusPlus/commit/39cd44bd54e918d25ee464477992ad0dc234dcba.patch";
23 sha256 = "sha256-PP6ENNhPJMWrYDlTnr156XV8d5aX/VNX8v4vvi9ZiWo";
24 })
25 ];
26
27 postPatch = ''
28 substituteInPlace src/test/CMakeLists.txt \
29 --replace "add_subdirectory(gtest)" ""
30 '';
31
32 doCheck = true;
33
34 checkPhase = ''
35 runHook preCheck
36 LD_LIBRARY_PATH=$PWD/src/contrib:$PWD/src/core \
37 src/test/lucene++-tester
38 runHook postCheck
39 '';
40
41 postInstall = ''
42 mv $out/include/pkgconfig $out/lib/
43 cp $src/src/contrib/include/*h $out/include/lucene++/
44 '';
45
46 meta = {
47 description = "C++ port of the popular Java Lucene search engine";
48 homepage = "https://github.com/luceneplusplus/LucenePlusPlus";
49 license = with lib.licenses; [ asl20 lgpl3Plus ];
50 platforms = lib.platforms.linux;
51 };
52}