pyrox.dev
1############################################################################
2# This file mainly provides the `mathcomp` derivation, which is #
3# essentially a meta-package containing all core mathcomp libraries #
4# (ssreflect fingroup algebra solvable field character). They can be #
5# accessed individually through the passthrough attributes of mathcomp #
6# bearing the same names (mathcomp.ssreflect, etc). #
7############################################################################
8# Compiling a custom version of mathcomp using `mathcomp.override`. #
9# This is the replacement for the former `mathcomp_ config` function. #
10# See the documentation at doc/languages-frameworks/coq.section.md. #
11############################################################################
12
13{ lib, ncurses, graphviz, lua, fetchzip,
14 mkCoqDerivation, recurseIntoAttrs, withDoc ? false, single ? false,
15 coqPackages, coq, version ? null }@args:
16with builtins // lib;
17let
18 repo = "math-comp";
19 owner = "math-comp";
20 withDoc = single && (args.withDoc or false);
21 defaultVersion = with versions; switch coq.coq-version [
22 { case = range "8.14" "8.16"; out = "1.15.0"; }
23 { case = range "8.11" "8.15"; out = "1.14.0"; }
24 { case = range "8.11" "8.15"; out = "1.13.0"; }
25 { case = range "8.10" "8.13"; out = "1.12.0"; }
26 { case = range "8.7" "8.12"; out = "1.11.0"; }
27 { case = range "8.7" "8.11"; out = "1.10.0"; }
28 { case = range "8.7" "8.11"; out = "1.9.0"; }
29 { case = range "8.7" "8.9"; out = "1.8.0"; }
30 { case = range "8.6" "8.9"; out = "1.7.0"; }
31 { case = range "8.5" "8.7"; out = "1.6.4"; }
32 ] null;
33 release = {
34 "1.15.0".sha256 = "1bp0jxl35ms54s0mdqky15w9af03f3i0n06qk12k4gw1xzvwqv21";
35 "1.14.0".sha256 = "07yamlp1c0g5nahkd2gpfhammcca74ga2s6qr7a3wm6y6j5pivk9";
36 "1.13.0".sha256 = "0j4cz2y1r1aw79snkcf1pmicgzf8swbaf9ippz0vg99a572zqzri";
37 "1.12.0".sha256 = "1ccfny1vwgmdl91kz5xlmhq4wz078xm4z5wpd0jy5rn890dx03wp";
38 "1.11.0".sha256 = "06a71d196wd5k4wg7khwqb7j7ifr7garhwkd54s86i0j7d6nhl3c";
39 "1.10.0".sha256 = "1b9m6pwxxyivw7rgx82gn5kmgv2mfv3h3y0mmjcjfypi8ydkrlbv";
40 "1.9.0".sha256 = "0lid9zaazdi3d38l8042lczb02pw5m9wq0yysiilx891hgq2p81r";
41 "1.8.0".sha256 = "07l40is389ih8bi525gpqs3qp4yb2kl11r9c8ynk1ifpjzpnabwp";
42 "1.7.0".sha256 = "0wnhj9nqpx2bw6n1l4i8jgrw3pjajvckvj3lr4vzjb3my2lbxdd1";
43 "1.6.4".sha256 = "09ww48qbjsvpjmy1g9yhm0rrkq800ffq21p6fjkbwd34qvd82raz";
44 "1.6.1".sha256 = "1ilw6vm4dlsdv9cd7kmf0vfrh2kkzr45wrqr8m37miy0byzr4p9i";
45 };
46 releaseRev = v: "mathcomp-${v}";
47
48 # list of core mathcomp packages sorted by dependency order
49 packages = [ "ssreflect" "fingroup" "algebra" "solvable" "field" "character" "all" ];
50
51 mathcomp_ = package: let
52 mathcomp-deps = if package == "single" then []
53 else map mathcomp_ (head (splitList (pred.equal package) packages));
54 pkgpath = if package == "single" then "mathcomp" else "mathcomp/${package}";
55 pname = if package == "single" then "mathcomp" else "mathcomp-${package}";
56 pkgallMake = ''
57 echo "all.v" > Make
58 echo "-I ." >> Make
59 echo "-R . mathcomp.all" >> Make
60 '';
61 derivation = mkCoqDerivation ({
62 inherit version pname defaultVersion release releaseRev repo owner;
63
64 mlPlugin = versions.isLe "8.6" coq.coq-version;
65 nativeBuildInputs = optionals withDoc [ graphviz lua ];
66 buildInputs = [ ncurses ];
67 propagatedBuildInputs = mathcomp-deps;
68
69 buildFlags = optional withDoc "doc";
70
71 preBuild = ''
72 if [[ -f etc/utils/ssrcoqdep ]]
73 then patchShebangs etc/utils/ssrcoqdep
74 fi
75 if [[ -f etc/buildlibgraph ]]
76 then patchShebangs etc/buildlibgraph
77 fi
78 '' + ''
79 cd ${pkgpath}
80 '' + optionalString (package == "all") pkgallMake;
81
82 meta = {
83 homepage = "https://math-comp.github.io/";
84 license = licenses.cecill-b;
85 maintainers = with maintainers; [ vbgl jwiegley cohencyril ];
86 };
87 } // optionalAttrs (package != "single")
88 { passthru = genAttrs packages mathcomp_; }
89 // optionalAttrs withDoc {
90 htmldoc_template =
91 fetchzip {
92 url = "https://github.com/math-comp/math-comp.github.io/archive/doc-1.12.0.zip";
93 sha256 = "0y1352ha2yy6k2dl375sb1r68r1qi9dyyy7dyzj5lp9hxhhq69x8";
94 };
95 postBuild = ''
96 cp -rf _build_doc/* .
97 rm -r _build_doc
98 '';
99 postInstall =
100 let tgt = "$out/share/coq/${coq.coq-version}/"; in
101 optionalString withDoc ''
102 mkdir -p ${tgt}
103 cp -r htmldoc ${tgt}
104 cp -r $htmldoc_template/htmldoc_template/* ${tgt}/htmldoc/
105 '';
106 buildTargets = "doc";
107 extraInstallFlags = [ "-f Makefile.coq" ];
108 });
109 patched-derivation1 = derivation.overrideAttrs (o:
110 optionalAttrs (o.pname != null && o.pname == "mathcomp-all" &&
111 o.version != null && o.version != "dev" && versions.isLt "1.7" o.version)
112 { preBuild = ""; buildPhase = ""; installPhase = "echo doing nothing"; }
113 );
114 patched-derivation = patched-derivation1.overrideAttrs (o:
115 optionalAttrs (versions.isLe "8.7" coq.coq-version ||
116 (o.version != "dev" && versions.isLe "1.7" o.version))
117 {
118 installFlags = o.installFlags ++ [ "-f Makefile.coq" ];
119 }
120 );
121 in patched-derivation;
122in
123mathcomp_ (if single then "single" else "all")