pyrox.dev
1{ lib, stdenv, fetchFromGitHub, llvmPackages, ncurses, cmake, libxml2
2, symlinkJoin, breakpointHook, cudaPackages, enableCUDA ? false
3, libobjc, Cocoa, Foundation
4}:
5
6let
7 luajitRev = "50936d784474747b4569d988767f1b5bab8bb6d0";
8 luajitBase = "LuaJIT-${luajitRev}";
9 luajitArchive = "${luajitBase}.tar.gz";
10 luajitSrc = fetchFromGitHub {
11 owner = "LuaJIT";
12 repo = "LuaJIT";
13 rev = luajitRev;
14 sha256 = "1g87pl014b5v6z2nnhiwn3wf405skawszfr5wdzyfbx00j3kgxd0";
15 };
16
17 llvmMerged = symlinkJoin {
18 name = "llvmClangMerged";
19 paths = with llvmPackages; [
20 llvm.out
21 llvm.dev
22 llvm.lib
23 clang-unwrapped.out
24 clang-unwrapped.dev
25 clang-unwrapped.lib
26 ];
27 };
28
29 cuda = cudaPackages.cudatoolkit_11;
30
31 clangVersion = llvmPackages.clang-unwrapped.version;
32
33in stdenv.mkDerivation rec {
34 pname = "terra";
35 version = "1.0.6";
36
37 src = fetchFromGitHub {
38 owner = "terralang";
39 repo = "terra";
40 rev = "release-${version}";
41 sha256 = "1bs76ibzb469rlqs7slw8pm65csjq1nf0lqh6i9kcvbzavmdfds7";
42 };
43
44 nativeBuildInputs = [ cmake ];
45 buildInputs = [ llvmMerged ncurses libxml2 ]
46 ++ lib.optionals enableCUDA [ cuda ]
47 ++ lib.optionals stdenv.isDarwin [ libobjc Cocoa Foundation ];
48
49 cmakeFlags = [
50 "-DHAS_TERRA_VERSION=0"
51 "-DTERRA_VERSION=${version}"
52 "-DTERRA_LUA=luajit"
53 "-DCLANG_RESOURCE_DIR=${llvmMerged}/lib/clang/${clangVersion}"
54 ] ++ lib.optional enableCUDA "-DTERRA_ENABLE_CUDA=ON";
55
56 doCheck = true;
57 hardeningDisable = [ "fortify" ];
58 outputs = [ "bin" "dev" "out" "static" ];
59
60 patches = [ ./nix-cflags.patch ];
61
62 postPatch = ''
63 sed -i '/file(DOWNLOAD "''${LUAJIT_URL}" "''${LUAJIT_TAR}")/d' \
64 cmake/Modules/GetLuaJIT.cmake
65
66 substituteInPlace src/terralib.lua \
67 --subst-var-by NIX_LIBC_INCLUDE ${lib.getDev stdenv.cc.libc}/include
68 '';
69
70 preConfigure = ''
71 mkdir -p build
72 ln -s ${luajitSrc} build/${luajitBase}
73 tar --mode="a+rwX" -chzf build/${luajitArchive} -C build ${luajitBase}
74 rm build/${luajitBase}
75 '';
76
77 installPhase = ''
78 install -Dm755 -t $bin/bin bin/terra
79 install -Dm755 -t $out/lib lib/terra${stdenv.hostPlatform.extensions.sharedLibrary}
80 install -Dm644 -t $static/lib lib/libterra_s.a
81
82 mkdir -pv $dev/include
83 cp -rv include/terra $dev/include
84 '';
85
86 meta = with lib; {
87 description = "A low-level counterpart to Lua";
88 homepage = "https://terralang.org/";
89 platforms = platforms.all;
90 maintainers = with maintainers; [ jb55 seylerius thoughtpolice elliottslaughter ];
91 license = licenses.mit;
92 };
93}