pyrox.dev
1{ lib, buildLinux, fetchurl
2, kernelPatches ? [ ]
3, structuredExtraConfig ? {}
4, extraMeta ? {}
5, argsOverride ? {}
6, ... } @ args:
7
8let
9 version = "5.4.154-rt65"; # updated by ./update-rt.sh
10 branch = lib.versions.majorMinor version;
11 kversion = builtins.elemAt (lib.splitString "-" version) 0;
12in buildLinux (args // {
13 inherit version;
14
15 src = fetchurl {
16 url = "mirror://kernel/linux/kernel/v5.x/linux-${kversion}.tar.xz";
17 sha256 = "01iwbz1ncakw90yykdw3cx04wnclwf1qa8nmlis08svbcvs99285";
18 };
19
20 kernelPatches = let rt-patch = {
21 name = "rt";
22 patch = fetchurl {
23 url = "mirror://kernel/linux/kernel/projects/rt/${branch}/older/patch-${version}.patch.xz";
24 sha256 = "0vbcmwg91hzcxiwq9dj550bw24k8r7lk61j06nwcnwmjg9a3g449";
25 };
26 }; in [ rt-patch ] ++ kernelPatches;
27
28 structuredExtraConfig = with lib.kernel; {
29 PREEMPT_RT = yes;
30 # Fix error: unused option: PREEMPT_RT.
31 EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
32 # Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
33 PREEMPT_VOLUNTARY = lib.mkForce no; # PREEMPT_RT deselects it.
34 # Fix error: unused option: RT_GROUP_SCHED.
35 RT_GROUP_SCHED = lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
36 } // structuredExtraConfig;
37
38 extraMeta = extraMeta // {
39 inherit branch;
40 };
41} // argsOverride)