pyrox.dev
1{ stdenvNoCC, lib, fetchzip, pkgs
2}:
3let
4
5 prebuilt_crt = fetchzip {
6 url = "https://android.googlesource.com/platform/prebuilts/gcc/linux-x86/aarch64/aarch64-linux-android-4.9/+archive/98dce673ad97a9640c5d90bbb1c718e75c21e071/lib/gcc/aarch64-linux-android/4.9.x.tar.gz";
7 sha256 = "sha256-LLD2OJi78sNN5NulOsJZl7Ei4F1EUYItGG6eUsKWULc=";
8 stripRoot = false;
9 };
10
11 prebuilt_libs = fetchzip {
12 url = "https://android.googlesource.com/platform/prebuilts/ndk/+archive/f2c77d8ba8a7f5c2d91771e31164f29be0b8ff98/platform/platforms/android-30/arch-arm64/usr/lib.tar.gz";
13 sha256 = "sha256-TZBV7+D1QvKOCEi+VNGT5SStkgj0xRbyWoLH65zSrjw=";
14 stripRoot = false;
15 };
16
17 prebuilt_ndk_crt = fetchzip {
18 url = "https://android.googlesource.com/toolchain/prebuilts/ndk/r23/+archive/6c5fa4c0d3999b9ee932f6acbd430eb2f31f3151/toolchains/llvm/prebuilt/linux-x86_64/sysroot/usr/lib/aarch64-linux-android/30.tar.gz";
19 sha256 = "sha256-KHw+cCwAwlm+5Nwp1o8WONqdi4BBDhFaVVr+7GxQ5uE=";
20 stripRoot = false;
21 };
22
23 ndk_support_headers = fetchzip {
24 url ="https://android.googlesource.com/platform/prebuilts/clang/host/linux-x86/+archive/0e7f808fa26cce046f444c9616d9167dafbfb272/clang-r416183b/include/c++/v1/support.tar.gz";
25 sha256 = "sha256-NBv7Pk1CEaz8ns9moleEERr3x/rFmVmG33LgFSeO6fY=";
26 stripRoot = false;
27 };
28
29 kernelHeaders = pkgs.makeLinuxHeaders {
30 version = "android-common-11-5.4";
31 src = fetchzip {
32 url = "https://android.googlesource.com/kernel/common/+archive/48ffcbf0b9e7f0280bfb8c32c68da0aaf0fdfef6.tar.gz";
33 sha256 = "1y7cmlmcr5vdqydd9n785s139yc4aylc3zhqa59xsylmkaf5habk";
34 stripRoot = false;
35 };
36 };
37
38in
39stdenvNoCC.mkDerivation rec {
40 pname = "bionic-prebuilt";
41 version = "ndk-release-r23";
42
43 src = fetchzip {
44 url = "https://android.googlesource.com/platform/bionic/+archive/00e8ce1142d8823b0d2fc8a98b40119b0f1f02cd.tar.gz";
45 sha256 = "10z5mp4w0acvjvgxv7wlqa7m70hcyarmjdlfxbd9rwzf4mrsr8d1";
46 stripRoot = false;
47 };
48
49 NIX_DONT_SET_RPATH = true;
50
51 dontConfigure = true;
52 dontBuild = true;
53
54 patches = [
55 ./ndk-version.patch
56 ];
57
58 postPatch = ''
59 substituteInPlace libc/include/sys/cdefs.h --replace \
60 "__has_builtin(__builtin_umul_overflow)" "1"
61 substituteInPlace libc/include/bits/ioctl.h --replace \
62 "!defined(BIONIC_IOCTL_NO_SIGNEDNESS_OVERLOAD)" "0"
63 '';
64
65 installPhase= ''
66 # copy the bionic headers
67 mkdir -p $out/include/support $out/include/android
68 cp -vr libc/include/* $out/include
69 # copy the kernel headers
70 cp -vr ${kernelHeaders}/include/* $out/include/
71
72 chmod -R +w $out/include/linux
73
74 # fix a bunch of kernel headers so that things can actually be found
75 sed -i 's,struct epoll_event {,#include <bits/epoll_event.h>\nstruct Xepoll_event {,' $out/include/linux/eventpoll.h
76 sed -i 's,struct in_addr {,typedef unsigned int in_addr_t;\nstruct in_addr {,' $out/include/linux/in.h
77 sed -i 's,struct udphdr {,struct Xudphdr {,' $out/include/linux/udp.h
78 sed -i 's,union semun {,union Xsemun {,' $out/include/linux/sem.h
79 sed -i 's,struct __kernel_sockaddr_storage,#define sockaddr_storage __kernel_sockaddr_storage\nstruct __kernel_sockaddr_storage,' $out/include/linux/socket.h
80 sed -i 's,#ifndef __UAPI_DEF_.*$,#if 1,' $out/include/linux/libc-compat.h
81 substituteInPlace $out/include/linux/in.h --replace "__be32 imr_" "struct in_addr imr_"
82 substituteInPlace $out/include/linux/in.h --replace "__be32 imsf_" "struct in_addr imsf_"
83 substituteInPlace $out/include/linux/sysctl.h --replace "__unused" "_unused"
84
85 # what could possibly live in <linux/compiler.h>
86 touch $out/include/linux/compiler.h
87
88 # copy the support headers
89 cp -vr ${ndk_support_headers}* $out/include/support/
90
91 mkdir $out/lib
92 cp -v ${prebuilt_crt.out}/*.o $out/lib/
93 cp -v ${prebuilt_crt.out}/libgcc.a $out/lib/
94 cp -v ${prebuilt_ndk_crt.out}/*.o $out/lib/
95 for i in libc.so libm.so libdl.so liblog.so; do
96 cp -v ${prebuilt_libs.out}/$i $out/lib/
97 done
98
99 mkdir -p $dev/include
100 cp -v $out/include/*.h $dev/include/
101 '';
102
103 outputs = [ "out" "dev" ];
104 passthru.linuxHeaders = kernelHeaders;
105
106 meta = with lib; {
107 description = "The Android libc implementation";
108 homepage = "https://android.googlesource.com/platform/bionic/";
109 license = licenses.mit;
110 platforms = platforms.linux;
111 maintainers = with maintainers; [ s1341 ];
112 };
113}