pyrox.dev
1{ stdenv, lib, buildPythonPackage, fetchPypi, pythonOlder
2, pipInstallHook, writeText
3, blessed
4, docutils
5, libcxx
6, llvm
7, pytestCheckHook
8, typesentry
9}:
10
11buildPythonPackage rec {
12 pname = "datatable";
13 version = "0.11.0";
14 disabled = pythonOlder "3.5";
15
16 src = fetchPypi {
17 inherit pname version;
18 sha256 = "19c602711e00f72e9ae296d8fa742d46da037c2d3a2d254bdf68f817a8da76bb";
19 };
20 # authors seem to have created their own build system
21 format = "other";
22
23 # tarball doesn't appear to have been shipped totally ready-to-build
24 postPatch = ''
25 substituteInPlace ci/ext.py \
26 --replace \
27 'shell_cmd(["git"' \
28 '"0000000000000000000000000000000000000000" or shell_cmd(["git"'
29 echo '${version}' > VERSION.txt
30 '';
31 DT_RELEASE = "1";
32
33 buildPhase = ''
34 python ci/ext.py wheel
35 '';
36
37 propagatedBuildInputs = [ typesentry blessed ];
38 buildInputs = [ llvm pipInstallHook ];
39 checkInputs = [ docutils pytestCheckHook ];
40
41 LLVM = llvm;
42 NIX_CFLAGS_COMPILE = lib.optionalString stdenv.isDarwin "-isystem ${lib.getDev libcxx}/include/c++/v1";
43
44 pytestFlagsArray = let
45 # ini file (not included in tarball) required to change python_files setting,
46 pytestIni = writeText "pytest.ini" ''
47 [pytest]
48 python_files = test_*.py test-*.py
49 '';
50 in [
51 "-c ${pytestIni}"
52 ];
53 disabledTests = [
54 # skip tests which are irrelevant to our installation or use way too much memory
55 "test_xfunction_paths"
56 "test_fread_from_cmd2"
57 "test_cast_huge_to_str"
58 "test_create_large_string_column"
59 ];
60 pythonImportsCheck = [ "datatable" ];
61
62 meta = with lib; {
63 description = "data.table for Python";
64 homepage = "https://github.com/h2oai/datatable";
65 license = licenses.mpl20;
66 maintainers = with maintainers; [ abbradar ];
67 };
68}