pyrox.dev
1{ lib, stdenv, fetchFromGitHub, cmake, python3, libX11, libXxf86vm, libXrandr, vulkan-headers, libGL }:
2
3stdenv.mkDerivation rec {
4 pname = "openxr-loader";
5 version = "1.0.20";
6
7 src = fetchFromGitHub {
8 owner = "KhronosGroup";
9 repo = "OpenXR-SDK-Source";
10 rev = "release-${version}";
11 sha256 = "sha256-afyAHTyW9x2KxR1q/K3t5Dpv9OzATcYiSgiDn2S924E=";
12 };
13
14 nativeBuildInputs = [ cmake python3 ];
15 buildInputs = [ libX11 libXxf86vm libXrandr vulkan-headers libGL ];
16
17 cmakeFlags = [ "-DBUILD_TESTS=OFF" ];
18
19 outputs = [ "out" "dev" "layers" ];
20
21 postInstall = ''
22 mkdir -p "$layers/share"
23 mv "$out/share/openxr" "$layers/share"
24 # Use absolute paths in manifests so no LD_LIBRARY_PATH shenanigans are necessary
25 for file in "$layers/share/openxr/1/api_layers/explicit.d/"*; do
26 substituteInPlace "$file" --replace '"library_path": "lib' "\"library_path\": \"$layers/lib/lib"
27 done
28 mkdir -p "$layers/lib"
29 mv "$out/lib/libXrApiLayer"* "$layers/lib"
30 '';
31
32 meta = with lib; {
33 description = "Khronos OpenXR loader";
34 homepage = "https://www.khronos.org/openxr";
35 platforms = platforms.linux;
36 license = licenses.asl20;
37 maintainers = [ maintainers.ralith ];
38 };
39}