pyrox.dev
1{ lib, stdenv, fetchgit, ant, jdk8, git, xorg, udev, libGL, libGLU }:
2
3{
4 jogl_2_3_2 =
5 let
6 version = "2.3.2";
7
8 gluegen-src = fetchgit {
9 url = "git://jogamp.org/srv/scm/gluegen.git";
10 rev = "v${version}";
11 sha256 = "00hybisjwqs88p24dds652bzrwbbmhn2dpx56kp4j6xpadkp33d0";
12 fetchSubmodules = true;
13 };
14 in stdenv.mkDerivation {
15 pname = "jogl";
16 inherit version;
17
18 src = fetchgit {
19 url = "git://jogamp.org/srv/scm/jogl.git";
20 rev = "v${version}";
21 sha256 = "0msi2gxiqm2yqwkmxqbh521xdrimw1fly20g890r357rcgj8fsn3";
22 fetchSubmodules = true;
23 };
24
25 postPatch = ''
26 find . -type f -name '*.java' \
27 -exec sed -i 's@"libGL.so"@"${libGL}/lib/libGL.so"@' {} \; \
28 -exec sed -i 's@"libGLU.so"@"${libGLU}/lib/libGLU.so"@' {} \;
29 '';
30
31 # TODO: upgrade to jdk https://github.com/NixOS/nixpkgs/pull/89731
32 nativeBuildInputs = [ jdk8 ant git ];
33 buildInputs = [ udev xorg.libX11 xorg.libXrandr xorg.libXcursor xorg.libXt xorg.libXxf86vm xorg.libXrender ];
34
35 buildPhase = ''
36 cp -r ${gluegen-src} $NIX_BUILD_TOP/gluegen
37 chmod -R +w $NIX_BUILD_TOP/gluegen
38 ( cd ../gluegen/make
39 ant )
40
41 ( cd make
42
43 # force way to do disfunctional "ant -Dsetup.addNativeBroadcom=false" and disable dependency on raspberrypi drivers
44 # if arm/aarch64 support will be added, this block might be commented out on those platforms
45 # on x86 compiling with default "setup.addNativeBroadcom=true" leads to unsatisfied import "vc_dispmanx_resource_delete" in libnewt.so
46 cp build-newt.xml build-newt.xml.old
47 fgrep -v 'if="setup.addNativeBroadcom"' build-newt.xml.old > build-newt.xml
48
49 ant )
50 '';
51
52 installPhase = ''
53 mkdir -p $out/share/java
54 cp $NIX_BUILD_TOP/gluegen/build/gluegen-rt{,-natives-linux-amd64}.jar $out/share/java/
55 cp $NIX_BUILD_TOP/jogl/build/jar/jogl-all{,-natives-linux-amd64}.jar $out/share/java/
56 '';
57
58 meta = with lib; {
59 description = "Java libraries for 3D Graphics, Multimedia and Processing";
60 homepage = "https://jogamp.org/";
61 license = licenses.bsd3;
62 platforms = [ "x86_64-linux" ];
63 };
64 };
65}