pyrox.dev
lol
1{ lib, stdenv, fetchpatch, fetchurl, fetchzip
2# build tools
3, gfortran, m4, makeWrapper, patchelf, perl, which, python2
4, cmake
5# libjulia dependencies
6, libunwind, readline, utf8proc, zlib
7# standard library dependencies
8, curl, fftwSinglePrec, fftw, gmp, libgit2, mpfr, openlibm, openspecfun, pcre2
9# linear algebra
10, blas, lapack, arpack
11# Darwin frameworks
12, CoreServices, ApplicationServices
13}:
14
15
16let
17 majorVersion = "1";
18 minorVersion = "0";
19 maintenanceVersion = "4";
20 src_sha256 = "1dfx68wbrrzpbh74rla7i2g3r5z6wa1pxq3ahyfm5m27vfyjbkhg";
21
22 libuvVersion = "ed3700c849289ed01fe04273a7bf865340b2bd7e";
23 libuvSha256 = "137w666zsjw1p0ma3lf94d75hr1q45sgkfmbizkyji2qm57cnxjs";
24
25 dsfmtVersion = "2.2.3";
26 dsfmt = fetchurl {
27 url = "http://www.math.sci.hiroshima-u.ac.jp/~m-mat/MT/SFMT/dSFMT-src-${dsfmtVersion}.tar.gz";
28 sha256 = "03kaqbjbi6viz0n33dk5jlf6ayxqlsq4804n7kwkndiga9s4hd42";
29 };
30
31 libuv = fetchurl {
32 url = "https://api.github.com/repos/JuliaLang/libuv/tarball/${libuvVersion}";
33 sha256 = libuvSha256;
34 };
35
36 rmathVersion = "0.1";
37 rmath-julia = fetchurl {
38 url = "https://api.github.com/repos/JuliaLang/Rmath-julia/tarball/v${rmathVersion}";
39 sha256 = "1qyps217175qhid46l8f5i1v8i82slgp23ia63x2hzxwfmx8617p";
40 };
41
42 virtualenvVersion = "15.0.0";
43 virtualenv = fetchurl {
44 url = "mirror://pypi/v/virtualenv/virtualenv-${virtualenvVersion}.tar.gz";
45 sha256 = "06fw4liazpx5vf3am45q2pdiwrv0id7ckv7n6zmpml29x6vkzmkh";
46 };
47
48 libwhichVersion = "81e9723c0273d78493dc8c8ed570f68d9ce7e89e";
49 libwhich = fetchurl {
50 url = "https://api.github.com/repos/vtjnash/libwhich/tarball/${libwhichVersion}";
51 sha256 = "1p7zg31kpmpbmh1znrk1xrbd074agx13b9q4dcw8n2zrwwdlbz3b";
52 };
53
54 llvmVersion = "6.0.0";
55 llvm = fetchurl {
56 url = "http://releases.llvm.org/6.0.0/llvm-${llvmVersion}.src.tar.xz";
57 sha256 = "0224xvfg6h40y5lrbnb9qaq3grmdc5rg00xq03s1wxjfbf8krx8z";
58 };
59
60 suitesparseVersion = "4.4.5";
61 suitesparse = fetchurl {
62 url = "http://faculty.cse.tamu.edu/davis/SuiteSparse/SuiteSparse-${suitesparseVersion}.tar.gz";
63 sha256 = "1jcbxb8jx5wlcixzf6n5dca2rcfx6mlcms1k2rl5gp67ay3bix43";
64 };
65 version = "${majorVersion}.${minorVersion}.${maintenanceVersion}";
66in
67
68stdenv.mkDerivation rec {
69 pname = "julia";
70 inherit version;
71
72 src = fetchzip {
73 url = "https://github.com/JuliaLang/${pname}/releases/download/v${version}/${pname}-${version}.tar.gz";
74 sha256 = src_sha256;
75 };
76
77 nativeBuildInputs = [ cmake curl gfortran m4 makeWrapper patchelf perl python2 which ];
78 # cmake is only used to build the bundled deps
79 dontUseCmakeConfigure = true;
80
81 # We assert that compatible blas and lapack are used.
82 buildInputs = assert (blas.isILP64 == lapack.isILP64); [
83 arpack fftw fftwSinglePrec gmp libgit2 libunwind mpfr
84 pcre2.dev blas lapack openlibm openspecfun readline utf8proc
85 zlib
86 ]
87 ++ lib.optionals stdenv.isDarwin [CoreServices ApplicationServices]
88 ;
89
90 patches = [
91 ./patches/1.0/use-system-utf8proc-julia-1.0.patch
92 ];
93
94 postPatch = ''
95 patchShebangs . contrib
96 for i in backtrace cmdlineargs; do
97 mv test/$i.jl{,.off}
98 touch test/$i.jl
99 done
100 rm stdlib/Sockets/test/runtests.jl && touch stdlib/Sockets/test/runtests.jl
101 rm stdlib/Distributed/test/runtests.jl && touch stdlib/Distributed/test/runtests.jl
102 sed -e 's/Invalid Content-Type:/invalid Content-Type:/g' -i ./stdlib/LibGit2/test/libgit2.jl
103 sed -e 's/Failed to resolve /failed to resolve /g' -i ./stdlib/LibGit2/test/libgit2.jl
104 '';
105 prePatch = ''
106 mkdir deps/srccache
107 cp "${dsfmt}" "./deps/srccache/dsfmt-${dsfmtVersion}.tar.gz"
108 cp "${rmath-julia}" "./deps/srccache/Rmath-julia-${rmathVersion}.tar.gz"
109 cp "${libuv}" "./deps/srccache/libuv-${libuvVersion}.tar.gz"
110 cp "${virtualenv}" "./deps/srccache/virtualenv-${virtualenvVersion}.tar.gz"
111 cp "${libwhich}" "./deps/srccache/libwhich-${libwhichVersion}.tar.gz"
112 cp "${llvm}" "./deps/srccache/llvm-${llvmVersion}.src.tar.xz"
113 cp "${suitesparse}" "./deps/srccache/SuiteSparse-${suitesparseVersion}.tar.gz"
114 '';
115
116 makeFlags =
117 let
118 arch = lib.head (lib.splitString "-" stdenv.system);
119 march = {
120 x86_64 = stdenv.hostPlatform.gcc.arch or "x86-64";
121 i686 = "pentium4";
122 aarch64 = "armv8-a";
123 }.${arch}
124 or (throw "unsupported architecture: ${arch}");
125 # Julia requires Pentium 4 (SSE2) or better
126 cpuTarget = { x86_64 = "x86-64"; i686 = "pentium4"; aarch64 = "generic"; }.${arch}
127 or (throw "unsupported architecture: ${arch}");
128 in [
129 "ARCH=${arch}"
130 "MARCH=${march}"
131 "JULIA_CPU_TARGET=${cpuTarget}"
132 "PREFIX=$(out)"
133 "prefix=$(out)"
134 "SHELL=${stdenv.shell}"
135
136 (lib.optionalString (!stdenv.isDarwin) "USE_SYSTEM_BLAS=1")
137 "USE_BLAS64=${if blas.isILP64 then "1" else "0"}"
138
139 "USE_SYSTEM_LAPACK=1"
140
141 "USE_SYSTEM_ARPACK=1"
142 "USE_SYSTEM_FFTW=1"
143 "USE_SYSTEM_GMP=1"
144 "USE_SYSTEM_LIBGIT2=1"
145 "USE_SYSTEM_LIBUNWIND=1"
146
147 # We will probably never do that
148 #"USE_SYSTEM_LLVM=1"
149 "LLVM_VER=6.0.0"
150
151 "USE_SYSTEM_MPFR=1"
152 "USE_SYSTEM_OPENLIBM=1"
153 "USE_SYSTEM_OPENSPECFUN=1"
154 "USE_SYSTEM_PATCHELF=1"
155 "USE_SYSTEM_PCRE=1"
156 "PCRE_CONFIG=${pcre2.dev}/bin/pcre2-config"
157 "PCRE_INCL_PATH=${pcre2.dev}/include/pcre2.h"
158 "USE_SYSTEM_READLINE=1"
159 "USE_SYSTEM_UTF8PROC=1"
160 "USE_SYSTEM_ZLIB=1"
161 ];
162
163 LD_LIBRARY_PATH = assert (blas.isILP64 == lapack.isILP64); (lib.makeLibraryPath [
164 arpack fftw fftwSinglePrec gmp libgit2 mpfr blas lapack openlibm
165 openspecfun pcre2
166 ]);
167
168 doCheck = !stdenv.isDarwin;
169 checkTarget = "testall";
170 # Julia's tests require read/write access to $HOME
171 preCheck = ''
172 export HOME="$NIX_BUILD_TOP"
173 '';
174
175 preBuild = ''
176 sed -e '/^install:/s@[^ ]*/doc/[^ ]*@@' -i Makefile
177 sed -e '/[$](DESTDIR)[$](docdir)/d' -i Makefile
178 export LD_LIBRARY_PATH=${LD_LIBRARY_PATH}
179 '';
180
181 enableParallelBuilding = true;
182
183 postInstall = ''
184 # Symlink shared libraries from LD_LIBRARY_PATH into lib/julia,
185 # as using a wrapper with LD_LIBRARY_PATH causes segmentation
186 # faults when program returns an error:
187 # $ julia -e 'throw(Error())'
188 find $(echo $LD_LIBRARY_PATH | sed 's|:| |g') -maxdepth 1 -name '*.${if stdenv.isDarwin then "dylib" else "so"}*' | while read lib; do
189 if [[ ! -e $out/lib/julia/$(basename $lib) ]]; then
190 ln -sv $lib $out/lib/julia/$(basename $lib)
191 fi
192 done
193 '';
194
195 passthru = {
196 inherit majorVersion minorVersion maintenanceVersion;
197 site = "share/julia/site/v${majorVersion}.${minorVersion}";
198 };
199
200 meta = {
201 description = "High-level performance-oriented dynamical language for technical computing";
202 homepage = "https://julialang.org/";
203 license = lib.licenses.mit;
204 maintainers = with lib.maintainers; [ raskin rob garrison ];
205 platforms = [ "i686-linux" "x86_64-linux" "x86_64-darwin" "aarch64-linux" ];
206 };
207}