pyrox.dev
1{ lib, stdenv, fetchFromGitHub, cmake, libuuid, gnutls, python3, xdg-utils }:
2
3stdenv.mkDerivation rec {
4 pname = "taskwarrior";
5 version = "2.6.1";
6
7 src = fetchFromGitHub {
8 owner = "GothenburgBitFactory";
9 repo = "taskwarrior";
10 rev = "v${version}";
11 sha256 = "sha256-jMZzo2cegoapEHTvfD6ThU1IsXru3iOcpyDbZxkSXzQ=";
12 fetchSubmodules = true;
13 };
14
15 postPatch = ''
16 substituteInPlace src/commands/CmdNews.cpp \
17 --replace "xdg-open" "${lib.getBin xdg-utils}/bin/xdg-open"
18 '';
19
20 nativeBuildInputs = [ cmake libuuid gnutls python3 ];
21
22 doCheck = true;
23 preCheck = ''
24 patchShebangs --build test
25 '';
26 checkTarget = "test";
27
28 postInstall = ''
29 mkdir -p "$out/share/bash-completion/completions"
30 ln -s "../../doc/task/scripts/bash/task.sh" "$out/share/bash-completion/completions/task.bash"
31 mkdir -p "$out/share/fish/vendor_completions.d"
32 ln -s "../../../share/doc/task/scripts/fish/task.fish" "$out/share/fish/vendor_completions.d/"
33 '';
34
35 meta = with lib; {
36 description = "Highly flexible command-line tool to manage TODO lists";
37 homepage = "https://taskwarrior.org";
38 license = licenses.mit;
39 maintainers = with maintainers; [ marcweber oxalica ];
40 platforms = platforms.unix;
41 };
42}