pyrox.dev
1{ lib, stdenv, fetchurl, appimageTools, makeWrapper, electron_13 }:
2
3stdenv.mkDerivation rec {
4 pname = "logseq";
5 version = "0.4.6";
6
7 src = fetchurl {
8 url = "https://github.com/logseq/logseq/releases/download/${version}/logseq-linux-x64-${version}.AppImage";
9 sha256 = "fGRPuv98sr3wcVbkVCJr2yKxBZ/IiQP854T9NBf/vCk=";
10 name = "${pname}-${version}.AppImage";
11 };
12
13 appimageContents = appimageTools.extract {
14 name = "${pname}-${version}";
15 inherit src;
16 };
17
18 dontUnpack = true;
19 dontConfigure = true;
20 dontBuild = true;
21
22 nativeBuildInputs = [ makeWrapper ];
23
24 installPhase = ''
25 runHook preInstall
26
27 mkdir -p $out/bin $out/share/${pname} $out/share/applications
28 cp -a ${appimageContents}/{locales,resources} $out/share/${pname}
29 cp -a ${appimageContents}/Logseq.desktop $out/share/applications/${pname}.desktop
30
31 substituteInPlace $out/share/applications/${pname}.desktop \
32 --replace Exec=Logseq Exec=${pname} \
33 --replace Icon=Logseq Icon=$out/share/${pname}/resources/app/icons/logseq.png
34
35 runHook postInstall
36 '';
37
38 postFixup = ''
39 makeWrapper ${electron_13}/bin/electron $out/bin/${pname} \
40 --add-flags $out/share/${pname}/resources/app
41 '';
42
43 passthru.updateScript = ./update.sh;
44
45 meta = with lib; {
46 description = "A local-first, non-linear, outliner notebook for organizing and sharing your personal knowledge base";
47 homepage = "https://github.com/logseq/logseq";
48 license = licenses.agpl3Plus;
49 maintainers = with maintainers; [ weihua ];
50 platforms = [ "x86_64-linux" ];
51 };
52}