pyrox.dev
1{ stdenv, fetchurl, autoconf, automake, pkgconfig
2, perl, flex, bison, readline, libexif
3, x11Support ? true, SDL
4, svgSupport ? true, inkscape
5, asciiArtSupport ? true, aalib
6, gifSupport ? true, giflib
7, tiffSupport ? true, libtiff
8, jpegSupport ? true, libjpeg
9, pngSupport ? true, libpng
10}:
11
12stdenv.mkDerivation rec {
13 name = "fim-${version}";
14 version = "0.6";
15
16 src = fetchurl {
17 url = "mirror://savannah/fbi-improved/${name}-trunk.tar.gz";
18 sha256 = "124b7c4flx5ygmy5sqq0gpvxqzafnknbcj6f45ddnbdxik9lazzp";
19 };
20
21 postPatch = ''
22 substituteInPlace doc/vim2html.pl \
23 --replace /usr/bin/perl ${perl}/bin/perl
24 '';
25
26 nativeBuildInputs = [ autoconf automake pkgconfig ];
27
28 buildInputs = with stdenv.lib;
29 [ perl flex bison readline libexif ]
30 ++ optional x11Support SDL
31 ++ optional svgSupport inkscape
32 ++ optional asciiArtSupport aalib
33 ++ optional gifSupport giflib
34 ++ optional tiffSupport libtiff
35 ++ optional jpegSupport libjpeg
36 ++ optional pngSupport libpng;
37
38 NIX_CFLAGS_COMPILE = stdenv.lib.optional x11Support "-lSDL";
39
40 meta = with stdenv.lib; {
41 description = "A lightweight, highly customizable and scriptable image viewer";
42 longDescription = ''
43 FIM (Fbi IMproved) is a lightweight, console based image viewer that aims
44 to be a highly customizable and scriptable for users who are comfortable
45 with software like the VIM text editor or the Mutt mail user agent.
46 '';
47 homepage = http://www.nongnu.org/fbi-improved/;
48 license = licenses.gpl2Plus;
49 platforms = platforms.linux;
50 maintainers = with maintainers; [ primeos ];
51 };
52}