pyrox.dev
1{ stdenv, buildPackages, fetchurl, attr, perl, pam }:
2
3stdenv.mkDerivation rec {
4 name = "libcap-${version}";
5 version = "2.25";
6
7 src = fetchurl {
8 url = "mirror://kernel/linux/libs/security/linux-privs/libcap2/${name}.tar.xz";
9 sha256 = "0qjiqc5pknaal57453nxcbz3mn1r4hkyywam41wfcglq3v2qlg39";
10 };
11
12 outputs = [ "out" "dev" "lib" "man" "doc" "pam" ];
13
14 depsBuildBuild = [ buildPackages.stdenv.cc ];
15 nativeBuildInputs = [ perl ];
16
17 buildInputs = [ pam ];
18
19 propagatedBuildInputs = [ attr ];
20
21 makeFlags = [
22 "lib=lib"
23 "PAM_CAP=yes"
24 "BUILD_CC=$(CC_FOR_BUILD)"
25 "CC:=$(CC)"
26 ];
27
28 prePatch = ''
29 # use relative bash path
30 substituteInPlace progs/capsh.c --replace "/bin/bash" "bash"
31
32 # ensure capsh can find bash in $PATH
33 substituteInPlace progs/capsh.c --replace execve execvpe
34
35 # set prefixes
36 substituteInPlace Make.Rules \
37 --replace 'prefix=/usr' "prefix=$lib" \
38 --replace 'exec_prefix=' "exec_prefix=$out" \
39 --replace 'lib_prefix=$(exec_prefix)' "lib_prefix=$lib" \
40 --replace 'inc_prefix=$(prefix)' "inc_prefix=$dev" \
41 --replace 'man_prefix=$(prefix)' "man_prefix=$doc"
42 '';
43
44 installFlags = "RAISE_SETFCAP=no";
45
46 postInstall = ''
47 rm "$lib"/lib/*.a
48 mkdir -p "$doc/share/doc/${name}"
49 cp License "$doc/share/doc/${name}/"
50 '' + stdenv.lib.optionalString (pam != null) ''
51 mkdir -p "$pam/lib/security"
52 mv "$lib"/lib/security "$pam/lib"
53 '';
54
55 meta = {
56 description = "Library for working with POSIX capabilities";
57 platforms = stdenv.lib.platforms.linux;
58 license = stdenv.lib.licenses.bsd3;
59 };
60}