pyrox.dev
1{ stdenv, fetchurl, foomatic-filters, bc, unzip, ghostscript, systemd, vim, time }:
2
3stdenv.mkDerivation rec {
4 name = "foo2zjs-20180519";
5
6 src = fetchurl {
7 url = "http://www.loegria.net/mirrors/foo2zjs/${name}.tar.gz";
8 sha256 = "1rmw4jmxn2lqp124mapvnic0ma8ipyvisx2vj848mvad5g5w9x3z";
9 };
10
11 buildInputs = [ foomatic-filters bc unzip ghostscript systemd vim ];
12
13 patches = [ ./no-hardcode-fw.diff ];
14
15 makeFlags = [
16 "PREFIX=$(out)"
17 "APPL=$(out)/share/applications"
18 "PIXMAPS=$(out)/share/pixmaps"
19 "UDEVBIN=$(out)/bin"
20 "UDEVDIR=$(out)/etc/udev/rules.d"
21 "UDEVD=${systemd}/sbin/udevd"
22 "LIBUDEVDIR=$(out)/lib/udev/rules.d"
23 "USBDIR=$(out)/etc/hotplug/usb"
24 "FOODB=$(out)/share/foomatic/db/source"
25 "MODEL=$(out)/share/cups/model"
26 ];
27
28 installFlags = [ "install-hotplug" ];
29
30 postPatch = ''
31 touch all-test
32 sed -e "/BASENAME=/iPATH=$out/bin:$PATH" -i *-wrapper *-wrapper.in
33 sed -e "s@PREFIX=/usr@PREFIX=$out@" -i *-wrapper{,.in}
34 sed -e "s@/usr/share@$out/share@" -i hplj10xx_gui.tcl
35 sed -e "s@\[.*-x.*/usr/bin/logger.*\]@type logger >/dev/null 2>\&1@" -i *wrapper{,.in}
36 sed -e '/install-usermap/d' -i Makefile
37 sed -e "s@/etc/hotplug/usb@$out&@" -i *rules*
38 sed -e "s@/usr@$out@g" -i hplj1020.desktop
39 sed -e "/PRINTERID=/s@=.*@=$out/bin/usb_printerid@" -i hplj1000
40 '';
41
42 checkInputs = [ time ];
43 doCheck = false; # fails to find its own binary. Also says "Tests will pass only if you are using ghostscript-8.71-16.fc14".
44
45 preInstall = ''
46 mkdir -pv $out/{etc/udev/rules.d,lib/udev/rules.d,etc/hotplug/usb}
47 mkdir -pv $out/share/foomatic/db/source/{opt,printer,driver}
48 mkdir -pv $out/share/cups/model
49 mkdir -pv $out/share/{applications,pixmaps}
50
51 mkdir -pv "$out/bin"
52 cp -v getweb arm2hpdl "$out/bin"
53 '';
54
55 meta = with stdenv.lib; {
56 description = "ZjStream printer drivers";
57 maintainers = with maintainers;
58 [
59 raskin
60 ];
61 platforms = platforms.linux;
62 license = licenses.gpl2Plus;
63 };
64}