pyrox.dev
1{ stdenv, fetchurl, makeWrapper, jre
2, htmlunit-driver, chromedriver, chromeSupport ? true }:
3
4with stdenv.lib;
5
6let
7 minorVersion = "3.6";
8 patchVersion = "0";
9
10in stdenv.mkDerivation rec {
11 name = "selenium-server-standalone-${version}";
12 version = "${minorVersion}.${patchVersion}";
13
14 src = fetchurl {
15 url = "http://selenium-release.storage.googleapis.com/${minorVersion}/selenium-server-standalone-${version}.jar";
16 sha256 = "11v340nm8vzqc2bkmbjfm9a7j4dj0bi9bfk8wdpfan0fb8prf772";
17 };
18
19 unpackPhase = "true";
20
21 buildInputs = [ jre makeWrapper ];
22
23 installPhase = ''
24 mkdir -p $out/share/lib/${name}
25 cp $src $out/share/lib/${name}/${name}.jar
26 makeWrapper ${jre}/bin/java $out/bin/selenium-server \
27 --add-flags "-cp $out/share/lib/${name}/${name}.jar:${htmlunit-driver}/share/lib/${htmlunit-driver.name}/${htmlunit-driver.name}.jar" \
28 --add-flags ${optionalString chromeSupport "-Dwebdriver.chrome.driver=${chromedriver}/bin/chromedriver"} \
29 --add-flags "org.openqa.grid.selenium.GridLauncherV3"
30 '';
31
32 meta = {
33 homepage = http://www.seleniumhq.org/;
34 description = "Selenium Server for remote WebDriver";
35 maintainers = with maintainers; [ coconnor offline ];
36 platforms = platforms.all;
37 license = licenses.asl20;
38 };
39}