pyrox.dev
lol
1{ enableMultiThreading ? false
2, enableG3toG4 ? false
3, enableInventor ? false
4, enableGDML ? false
5, enableQT ? false
6, enableXM ? false
7, enableOpenGLX11 ? false
8, enableRaytracerX11 ? false
9
10# Standard build environment with cmake.
11, stdenv, fetchurl, cmake
12
13# Optional system packages, otherwise internal GEANT4 packages are used.
14, clhep ? null
15, expat ? null
16, zlib ? null
17
18# For enableGDML.
19, xercesc ? null
20
21# For enableQT.
22, qt ? null # qt4SDK or qt5SDK
23
24# For enableXM.
25, motif ? null # motif or lesstif
26
27# For enableInventor
28, coin3d
29, soxt
30, libXpm ? null
31
32# For enableQT, enableXM, enableOpenGLX11, enableRaytracerX11.
33, libGLU_combined ? null
34, xlibsWrapper ? null
35, libXmu ? null
36}:
37
38# G4persistency library with support for GDML
39assert enableGDML -> xercesc != null;
40
41# If enableQT, Qt4/5 User Interface and Visualization drivers.
42assert enableQT -> qt != null;
43
44# Motif User Interface and Visualisation drivers.
45assert enableXM -> motif != null;
46
47# OpenGL/X11 User Interface and Visualisation drivers.
48assert enableQT || enableXM || enableOpenGLX11 || enableRaytracerX11 -> libGLU_combined != null;
49assert enableQT || enableXM || enableOpenGLX11 || enableRaytracerX11 -> xlibsWrapper != null;
50assert enableQT || enableXM || enableOpenGLX11 || enableRaytracerX11 -> libXmu != null;
51assert enableInventor -> libXpm != null;
52
53let
54 buildGeant4 =
55 { version, src, multiThreadingCapable ? false }:
56
57 stdenv.mkDerivation rec {
58 inherit version src;
59 name = "geant4-${version}";
60
61 multiThreadingFlag = if multiThreadingCapable then "-DGEANT4_BUILD_MULTITHREADED=${if enableMultiThreading then "ON" else "OFF"}" else "";
62
63 cmakeFlags = ''
64 ${multiThreadingFlag}
65 -DGEANT4_INSTALL_DATA=OFF
66 -DGEANT4_USE_GDML=${if enableGDML then "ON" else "OFF"}
67 -DGEANT4_USE_G3TOG4=${if enableG3toG4 then "ON" else "OFF"}
68 -DGEANT4_USE_QT=${if enableQT then "ON" else "OFF"}
69 -DGEANT4_USE_XM=${if enableXM then "ON" else "OFF"}
70 -DGEANT4_USE_OPENGL_X11=${if enableOpenGLX11 then "ON" else "OFF"}
71 -DGEANT4_USE_INVENTOR=${if enableInventor then "ON" else "OFF"}
72 -DGEANT4_USE_RAYTRACER_X11=${if enableRaytracerX11 then "ON" else "OFF"}
73 -DGEANT4_USE_SYSTEM_CLHEP=${if clhep != null then "ON" else "OFF"}
74 -DGEANT4_USE_SYSTEM_EXPAT=${if expat != null then "ON" else "OFF"}
75 -DGEANT4_USE_SYSTEM_ZLIB=${if zlib != null then "ON" else "OFF"}
76 -DINVENTOR_INCLUDE_DIR=${coin3d}/include
77 -DINVENTOR_LIBRARY_RELEASE=${coin3d}/lib/libCoin.so
78 '';
79
80 enableParallelBuilding = true;
81 buildInputs = [ cmake clhep expat zlib xercesc qt motif libGLU_combined xlibsWrapper libXmu libXpm coin3d soxt ];
82 propagatedBuildInputs = [ clhep expat zlib xercesc qt motif libGLU_combined xlibsWrapper libXmu libXpm coin3d soxt ];
83
84 postFixup = ''
85 # Don't try to export invalid environment variables.
86 sed -i 's/export G4\([A-Z]*\)DATA/#export G4\1DATA/' "$out"/bin/geant4.sh
87 '';
88
89 setupHook = ./geant4-hook.sh;
90
91 passthru = {
92 data = import ./datasets.nix { inherit stdenv fetchurl; };
93 };
94
95 # Set the myriad of envars required by Geant4 if we use a nix-shell.
96 shellHook = ''
97 source $out/nix-support/setup-hook
98 '';
99
100 meta = with stdenv.lib; {
101 description = "A toolkit for the simulation of the passage of particles through matter";
102 longDescription = ''
103 Geant4 is a toolkit for the simulation of the passage of particles through matter.
104 Its areas of application include high energy, nuclear and accelerator physics, as well as studies in medical and space science.
105 The two main reference papers for Geant4 are published in Nuclear Instruments and Methods in Physics Research A 506 (2003) 250-303, and IEEE Transactions on Nuclear Science 53 No. 1 (2006) 270-278.
106 '';
107 homepage = http://www.geant4.org;
108 license = licenses.g4sl;
109 maintainers = with maintainers; [ tmplt ];
110 platforms = platforms.all;
111 };
112 };
113
114 fetchGeant4 = import ./fetch.nix {
115 inherit stdenv fetchurl;
116 };
117
118in {
119 v10_0_2 = buildGeant4 {
120 inherit (fetchGeant4.v10_0_2) version src;
121 multiThreadingCapable = true;
122 };
123
124 v10_4_1 = buildGeant4 {
125 inherit (fetchGeant4.v10_4_1) version src;
126 multiThreadingCapable = true;
127 };
128}