pyrox.dev
lol
1{ stdenv, fetchurl, libGLU, xlibsWrapper, libXmu, libXi
2, AGL ? null
3}:
4
5with stdenv.lib;
6
7stdenv.mkDerivation rec {
8 name = "glew-1.10.0";
9
10 src = fetchurl {
11 url = "mirror://sourceforge/glew/${name}.tgz";
12 sha256 = "01zki46dr5khzlyywr3cg615bcal32dazfazkf360s1znqh17i4r";
13 };
14
15 buildInputs = [ xlibsWrapper libXmu libXi ]
16 ++ optionals stdenv.isDarwin [ AGL ];
17 propagatedBuildInputs = [ libGLU ]; # GL/glew.h includes GL/glu.h
18
19 patchPhase = ''
20 sed -i 's|lib64|lib|' config/Makefile.linux
21 ${optionalString (stdenv.hostPlatform != stdenv.buildPlatform) ''
22 sed -i -e 's/\(INSTALL.*\)-s/\1/' Makefile
23 ''}
24 '';
25
26 buildFlags = [ "all" ];
27 installFlags = [ "install.all" ];
28
29 preInstall = ''
30 export GLEW_DEST="$out"
31 '';
32
33 postInstall = ''
34 mkdir -pv $out/share/doc/glew
35 mkdir -p $out/lib/pkgconfig
36 cp glew*.pc $out/lib/pkgconfig
37 cp -r README.txt LICENSE.txt doc $out/share/doc/glew
38 '';
39
40 makeFlags = [
41 "SYSTEM=${if stdenv.hostPlatform.isMinGW then "mingw" else stdenv.hostPlatform.parsed.kernel.name}"
42 ];
43
44 meta = with stdenv.lib; {
45 description = "An OpenGL extension loading library for C(++)";
46 homepage = http://glew.sourceforge.net/;
47 license = licenses.free; # different files under different licenses
48 #["BSD" "GLX" "SGI-B" "GPL2"]
49 platforms = platforms.mesaPlatforms;
50 };
51}