pyrox.dev
lol
1{ stdenv, lib, fetchurl, intltool, pkgconfig, gstreamer, gst-plugins-base
2, gst-plugins-good, gst-plugins-bad, gst-plugins-ugly, gst-ffmpeg, glib
3, mono, mono-addins, dbus-sharp-1_0, dbus-sharp-glib-1_0, notify-sharp, gtk-sharp-2_0
4, boo, gdata-sharp, taglib-sharp, sqlite, gnome-sharp, gconf, gtk-sharp-beans, gio-sharp
5, libmtp, libgpod, mono-zeroconf }:
6
7stdenv.mkDerivation rec {
8 name = "banshee-${version}";
9 version = "2.6.2";
10
11 src = fetchurl {
12 url = "https://ftp.gnome.org/pub/GNOME/sources/banshee/2.6/banshee-${version}.tar.xz";
13 sha256 = "1y30p8wxx5li39i5gpq2wib0ympy8llz0gyi6ri9bp730ndhhz7p";
14 };
15
16 dontStrip = true;
17
18 nativeBuildInputs = [ pkgconfig intltool ];
19 buildInputs = [
20 gtk-sharp-2_0.gtk gstreamer gst-plugins-base gst-plugins-good
21 gst-plugins-bad gst-plugins-ugly gst-ffmpeg
22 mono dbus-sharp-1_0 dbus-sharp-glib-1_0 mono-addins notify-sharp
23 gtk-sharp-2_0 boo gdata-sharp taglib-sharp sqlite gnome-sharp gconf gtk-sharp-beans
24 gio-sharp libmtp libgpod mono-zeroconf
25 ];
26
27 makeFlags = [ "PREFIX=$(out)" ];
28
29 postPatch = ''
30 patchShebangs data/desktop-files/update-desktop-file.sh
31 patchShebangs build/private-icon-theme-installer
32 sed -i "s,DOCDIR=.*,DOCDIR=$out/lib/monodoc," configure
33 '';
34
35 postInstall = let
36 ldLibraryPath = lib.makeLibraryPath [ gtk-sharp-2_0.gtk gtk-sharp-2_0 sqlite gconf glib gstreamer ];
37
38 monoGACPrefix = lib.concatStringsSep ":" [
39 mono dbus-sharp-1_0 dbus-sharp-glib-1_0 mono-addins notify-sharp gtk-sharp-2_0
40 boo gdata-sharp taglib-sharp sqlite gnome-sharp gconf gtk-sharp-beans
41 gio-sharp libmtp libgpod mono-zeroconf
42 ];
43 in ''
44 sed -e '2a export MONO_GAC_PREFIX=${monoGACPrefix}' \
45 -e 's|LD_LIBRARY_PATH=|LD_LIBRARY_PATH=${ldLibraryPath}:|' \
46 -e "s|GST_PLUGIN_PATH=|GST_PLUGIN_PATH=$GST_PLUGIN_SYSTEM_PATH:|" \
47 -e 's| mono | ${mono}/bin/mono |' \
48 -i $out/bin/banshee
49 '';
50 meta = with lib; {
51 homepage = "http://banshee.fm/";
52 description = "A music player written in C# using GNOME technologies";
53 platforms = platforms.linux;
54 maintainers = [ maintainers.zohl ];
55 license = licenses.mit;
56 };
57}