pyrox.dev
1{ stdenv, fetchurl, ncurses, perl, help2man }:
2
3stdenv.mkDerivation rec {
4 name = "inetutils-1.9.4";
5
6 src = fetchurl {
7 url = "mirror://gnu/inetutils/${name}.tar.gz";
8 sha256 = "05n65k4ixl85dc6rxc51b1b732gnmm8xnqi424dy9f1nz7ppb3xy";
9 };
10
11 patches = [
12 ./whois-Update-Canadian-TLD-server.patch
13 ./service-name.patch
14 ];
15
16 buildInputs = [ ncurses /* for `talk' */ perl /* for `whois' */ help2man ];
17
18 configureFlags = [ "--with-ncurses-include-dir=${ncurses.dev}/include" ]
19 ++ stdenv.lib.optionals stdenv.hostPlatform.isMusl [ # Musl doesn't define rcmd
20 "--disable-rcp"
21 "--disable-rsh"
22 "--disable-rlogin"
23 "--disable-rexec"
24 ];
25
26 # Test fails with "UNIX socket name too long", probably because our
27 # $TMPDIR is too long.
28 #doCheck = true;
29
30
31 postInstall = ''
32 # XXX: These programs are normally installed setuid but since it
33 # fails, they end up being non-executable, hence this hack.
34 chmod +x $out/bin/{ping,ping6,${stdenv.lib.optionalString (!stdenv.hostPlatform.isMusl) ''rcp,rlogin,rsh,''}traceroute}
35 '';
36
37 meta = {
38 description = "Collection of common network programs";
39
40 longDescription =
41 '' The GNU network utilities suite provides the
42 following tools: ftp(d), hostname, ifconfig, inetd, logger, ping, rcp,
43 rexec(d), rlogin(d), rsh(d), syslogd, talk(d), telnet(d), tftp(d),
44 traceroute, uucpd, and whois.
45 '';
46
47 homepage = http://www.gnu.org/software/inetutils/;
48 license = stdenv.lib.licenses.gpl3Plus;
49
50 maintainers = [ ];
51 platforms = stdenv.lib.platforms.gnu;
52 };
53}