pyrox.dev
1{ stdenv, fetchurl, fetchpatch, buildPackages
2, glibc
3, bzip2
4, expat
5, libffi
6, gdbm
7, lzma
8, ncurses
9, openssl
10, readline
11, sqlite
12, tcl ? null, tk ? null, tix ? null, libX11 ? null, xproto ? null, x11Support ? false
13, zlib
14, callPackage
15, self
16, CF, configd
17, python-setup-hook
18# For the Python package set
19, pkgs, packageOverrides ? (self: super: {})
20}:
21
22assert x11Support -> tcl != null
23 && tk != null
24 && xproto != null
25 && libX11 != null;
26with stdenv.lib;
27
28let
29 majorVersion = "3.6";
30 minorVersion = "4";
31 minorVersionSuffix = "";
32 pythonVersion = majorVersion;
33 version = "${majorVersion}.${minorVersion}${minorVersionSuffix}";
34 libPrefix = "python${majorVersion}";
35 sitePackages = "lib/${libPrefix}/site-packages";
36
37 buildInputs = filter (p: p != null) [
38 zlib bzip2 expat lzma libffi gdbm sqlite readline ncurses openssl ]
39 ++ optionals x11Support [ tcl tk libX11 xproto ]
40 ++ optionals stdenv.isDarwin [ CF configd ];
41
42 nativeBuildInputs =
43 optional (stdenv.hostPlatform != stdenv.buildPlatform) buildPackages.python3;
44
45in stdenv.mkDerivation {
46 name = "python3-${version}";
47 pythonVersion = majorVersion;
48 inherit majorVersion version;
49
50 inherit buildInputs nativeBuildInputs;
51
52 src = fetchurl {
53 url = "https://www.python.org/ftp/python/${majorVersion}.${minorVersion}/Python-${version}.tar.xz";
54 sha256 = "1fna7g8jxzl4kd2pqmmqhva5724c5m920x3fsrpsgskaylmr76qm";
55 };
56
57 NIX_LDFLAGS = optionalString stdenv.isLinux "-lgcc_s";
58
59 # Determinism: The interpreter is patched to write null timestamps when compiling python files.
60 # This way python doesn't try to update them when we freeze timestamps in nix store.
61 DETERMINISTIC_BUILD=1;
62 # Determinism: We fix the hashes of str, bytes and datetime objects.
63 PYTHONHASHSEED=0;
64
65 prePatch = optionalString stdenv.isDarwin ''
66 substituteInPlace configure --replace '`/usr/bin/arch`' '"i386"'
67 substituteInPlace configure --replace '-Wl,-stack_size,1000000' ' '
68 '';
69
70 patches = [
71 ./no-ldconfig.patch
72 ];
73
74 postPatch = ''
75 # Determinism
76 substituteInPlace "Lib/py_compile.py" --replace "source_stats['mtime']" "(1 if 'DETERMINISTIC_BUILD' in os.environ else source_stats['mtime'])"
77 # Determinism. This is done unconditionally
78 substituteInPlace "Lib/importlib/_bootstrap_external.py" --replace "source_mtime = int(st['mtime'])" "source_mtime = 1"
79 '' + optionalString (x11Support && (tix != null)) ''
80 substituteInPlace "Lib/tkinter/tix.py" --replace "os.environ.get('TIX_LIBRARY')" "os.environ.get('TIX_LIBRARY') or '${tix}/lib'"
81 '';
82
83 CPPFLAGS="${concatStringsSep " " (map (p: "-I${getDev p}/include") buildInputs)}";
84 LDFLAGS="${concatStringsSep " " (map (p: "-L${getLib p}/lib") buildInputs)}";
85 LIBS="${optionalString (!stdenv.isDarwin) "-lcrypt"} ${optionalString (ncurses != null) "-lncurses"}";
86
87 configureFlags = [
88 "--enable-shared"
89 "--with-threads"
90 "--without-ensurepip"
91 "--with-system-expat"
92 "--with-system-ffi"
93 ] ++ optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
94 "ac_cv_buggy_getaddrinfo=no"
95 # Assume little-endian IEEE 754 floating point when cross compiling
96 "ac_cv_little_endian_double=yes"
97 "ac_cv_big_endian_double=no"
98 "ac_cv_mixed_endian_double=no"
99 "ac_cv_x87_double_rounding=yes"
100 "ac_cv_tanh_preserves_zero_sign=yes"
101 # Generally assume that things are present and work
102 "ac_cv_posix_semaphores_enabled=yes"
103 "ac_cv_broken_sem_getvalue=no"
104 "ac_cv_wchar_t_signed=yes"
105 "ac_cv_rshift_extends_sign=yes"
106 "ac_cv_broken_nice=no"
107 "ac_cv_broken_poll=no"
108 "ac_cv_working_tzset=yes"
109 "ac_cv_have_long_long_format=yes"
110 "ac_cv_have_size_t_format=yes"
111 "ac_cv_computed_gotos=yes"
112 "ac_cv_file__dev_ptmx=yes"
113 "ac_cv_file__dev_ptc=yes"
114 ];
115
116 preConfigure = ''
117 for i in /usr /sw /opt /pkg; do # improve purity
118 substituteInPlace ./setup.py --replace $i /no-such-path
119 done
120 ${optionalString stdenv.isDarwin ''
121 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -msse2"
122 export MACOSX_DEPLOYMENT_TARGET=10.6
123 ''}
124 '';
125
126 setupHook = python-setup-hook sitePackages;
127
128 postInstall = ''
129 # needed for some packages, especially packages that backport functionality
130 # to 2.x from 3.x
131 for item in $out/lib/python${majorVersion}/test/*; do
132 if [[ "$item" != */test_support.py*
133 && "$item" != */test/support
134 && "$item" != */test/libregrtest
135 && "$item" != */test/regrtest.py* ]]; then
136 rm -rf "$item"
137 else
138 echo $item
139 fi
140 done
141 touch $out/lib/python${majorVersion}/test/__init__.py
142
143 ln -s "$out/include/python${majorVersion}m" "$out/include/python${majorVersion}"
144 paxmark E $out/bin/python${majorVersion}
145
146 # Python on Nix is not manylinux1 compatible. https://github.com/NixOS/nixpkgs/issues/18484
147 echo "manylinux1_compatible=False" >> $out/lib/${libPrefix}/_manylinux.py
148
149 # Determinism: Windows installers were not deterministic.
150 # We're also not interested in building Windows installers.
151 find "$out" -name 'wininst*.exe' | xargs -r rm -f
152
153 # Use Python3 as default python
154 ln -s "$out/bin/idle3" "$out/bin/idle"
155 ln -s "$out/bin/pydoc3" "$out/bin/pydoc"
156 ln -s "$out/bin/python3" "$out/bin/python"
157 ln -s "$out/bin/python3-config" "$out/bin/python-config"
158 ln -s "$out/lib/pkgconfig/python3.pc" "$out/lib/pkgconfig/python.pc"
159
160 # Get rid of retained dependencies on -dev packages, and remove
161 # some $TMPDIR references to improve binary reproducibility.
162 # Note that the .pyc file of _sysconfigdata.py should be regenerated!
163 for i in $out/lib/python${majorVersion}/_sysconfigdata*.py $out/lib/python${majorVersion}/config-${majorVersion}m*/Makefile; do
164 sed -i $i -e "s|-I/nix/store/[^ ']*||g" -e "s|-L/nix/store/[^ ']*||g" -e "s|$TMPDIR|/no-such-path|g"
165 done
166 '' + optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
167 # Determinism: rebuild all bytecode
168 # We exclude lib2to3 because that's Python 2 code which fails
169 # We rebuild three times, once for each optimization level
170 find $out -name "*.py" | $out/bin/python -m compileall -q -f -x "lib2to3" -i -
171 find $out -name "*.py" | $out/bin/python -O -m compileall -q -f -x "lib2to3" -i -
172 find $out -name "*.py" | $out/bin/python -OO -m compileall -q -f -x "lib2to3" -i -
173 '';
174
175 passthru = let
176 pythonPackages = callPackage ../../../../../top-level/python-packages.nix {python=self; overrides=packageOverrides;};
177 in rec {
178 inherit libPrefix sitePackages x11Support;
179 executable = "${libPrefix}m";
180 buildEnv = callPackage ../../wrapper.nix { python = self; inherit (pythonPackages) requiredPythonModules; };
181 withPackages = import ../../with-packages.nix { inherit buildEnv pythonPackages;};
182 pkgs = pythonPackages;
183 isPy3 = true;
184 isPy35 = true;
185 is_py3k = true; # deprecated
186 interpreter = "${self}/bin/${executable}";
187 };
188
189 enableParallelBuilding = true;
190
191 meta = {
192 homepage = http://python.org;
193 description = "A high-level dynamically-typed programming language";
194 longDescription = ''
195 Python is a remarkably powerful dynamic programming language that
196 is used in a wide variety of application domains. Some of its key
197 distinguishing features include: clear, readable syntax; strong
198 introspection capabilities; intuitive object orientation; natural
199 expression of procedural code; full modularity, supporting
200 hierarchical packages; exception-based error handling; and very
201 high level dynamic data types.
202 '';
203 license = licenses.psfl;
204 platforms = with platforms; linux ++ darwin;
205 maintainers = with maintainers; [ fridh kragniz ];
206 };
207}