pyrox.dev
1{ stdenv, fetchurl, fetchpatch
2, bzip2
3, expat
4, libffi
5, gdbm
6, lzma
7, ncurses
8, openssl
9, readline
10, sqlite
11, tcl ? null, tk ? null, tix ? null, libX11 ? null, xproto ? null, x11Support ? false
12, zlib
13, callPackage
14, self
15, CF, configd
16, python-setup-hook
17# For the Python package set
18, pkgs, packageOverrides ? (self: super: {})
19}:
20
21assert x11Support -> tcl != null
22 && tk != null
23 && xproto != null
24 && libX11 != null;
25
26with stdenv.lib;
27
28let
29 majorVersion = "3.5";
30 minorVersion = "5";
31 minorVersionSuffix = "";
32 pythonVersion = majorVersion;
33 version = "${majorVersion}.${minorVersion}${minorVersionSuffix}";
34 libPrefix = "python${majorVersion}";
35 sitePackages = "lib/${libPrefix}/site-packages";
36
37 buildInputs = filter (p: p != null) [
38 zlib bzip2 expat lzma libffi gdbm sqlite readline ncurses openssl ]
39 ++ optionals x11Support [ tcl tk libX11 xproto ]
40 ++ optionals stdenv.isDarwin [ CF configd ];
41
42in stdenv.mkDerivation {
43 name = "python3-${version}";
44 pythonVersion = majorVersion;
45 inherit majorVersion version;
46
47 inherit buildInputs;
48
49 src = fetchurl {
50 url = "https://www.python.org/ftp/python/${majorVersion}.${minorVersion}/Python-${version}.tar.xz";
51 sha256 = "02ahsijk3a42sdzfp2il49shx0v4birhy7kkj0dikmh20hxjqg86";
52 };
53
54 NIX_LDFLAGS = optionalString stdenv.isLinux "-lgcc_s";
55
56 # Determinism: The interpreter is patched to write null timestamps when compiling python files.
57 # This way python doesn't try to update them when we freeze timestamps in nix store.
58 DETERMINISTIC_BUILD=1;
59 # Determinism: We fix the hashes of str, bytes and datetime objects.
60 PYTHONHASHSEED=0;
61
62 prePatch = optionalString stdenv.isDarwin ''
63 substituteInPlace configure --replace '`/usr/bin/arch`' '"i386"'
64 substituteInPlace configure --replace '-Wl,-stack_size,1000000' ' '
65 '';
66
67 patches = [
68 ./no-ldconfig.patch
69 ./ld_library_path.patch
70 ];
71
72 postPatch = ''
73 # Determinism
74 substituteInPlace "Lib/py_compile.py" --replace "source_stats['mtime']" "(1 if 'DETERMINISTIC_BUILD' in os.environ else source_stats['mtime'])"
75 # Determinism. This is done unconditionally
76 substituteInPlace "Lib/importlib/_bootstrap_external.py" --replace "source_mtime = int(st['mtime'])" "source_mtime = 1"
77 '' + optionalString (x11Support && (tix != null)) ''
78 substituteInPlace "Lib/tkinter/tix.py" --replace "os.environ.get('TIX_LIBRARY')" "os.environ.get('TIX_LIBRARY') or '${tix}/lib'"
79 '';
80
81 CPPFLAGS="${concatStringsSep " " (map (p: "-I${getDev p}/include") buildInputs)}";
82 LDFLAGS="${concatStringsSep " " (map (p: "-L${getLib p}/lib") buildInputs)}";
83 LIBS="${optionalString (!stdenv.isDarwin) "-lcrypt"} ${optionalString (ncurses != null) "-lncurses"}";
84
85 configureFlags = [
86 "--enable-shared"
87 "--with-threads"
88 "--without-ensurepip"
89 "--with-system-expat"
90 "--with-system-ffi"
91 ];
92
93 preConfigure = ''
94 for i in /usr /sw /opt /pkg; do # improve purity
95 substituteInPlace ./setup.py --replace $i /no-such-path
96 done
97 ${optionalString stdenv.isDarwin ''
98 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -msse2"
99 export MACOSX_DEPLOYMENT_TARGET=10.6
100 ''}
101 '';
102
103 setupHook = python-setup-hook sitePackages;
104
105 postInstall = ''
106 # needed for some packages, especially packages that backport functionality
107 # to 2.x from 3.x
108 for item in $out/lib/python${majorVersion}/test/*; do
109 if [[ "$item" != */test_support.py*
110 && "$item" != */test/support
111 && "$item" != */test/libregrtest
112 && "$item" != */test/regrtest.py* ]]; then
113 rm -rf "$item"
114 else
115 echo $item
116 fi
117 done
118 touch $out/lib/python${majorVersion}/test/__init__.py
119
120 ln -s "$out/include/python${majorVersion}m" "$out/include/python${majorVersion}"
121 paxmark E $out/bin/python${majorVersion}
122
123 # Python on Nix is not manylinux1 compatible. https://github.com/NixOS/nixpkgs/issues/18484
124 echo "manylinux1_compatible=False" >> $out/lib/${libPrefix}/_manylinux.py
125
126 # Determinism: Windows installers were not deterministic.
127 # We're also not interested in building Windows installers.
128 find "$out" -name 'wininst*.exe' | xargs -r rm -f
129
130 # Use Python3 as default python
131 ln -s "$out/bin/idle3" "$out/bin/idle"
132 ln -s "$out/bin/pydoc3" "$out/bin/pydoc"
133 ln -s "$out/bin/python3" "$out/bin/python"
134 ln -s "$out/bin/python3-config" "$out/bin/python-config"
135 ln -s "$out/lib/pkgconfig/python3.pc" "$out/lib/pkgconfig/python.pc"
136
137 # Get rid of retained dependencies on -dev packages, and remove
138 # some $TMPDIR references to improve binary reproducibility.
139 # Note that the .pyc file of _sysconfigdata.py should be regenerated!
140 for i in $out/lib/python${majorVersion}/_sysconfigdata.py $out/lib/python${majorVersion}/config-${majorVersion}m/Makefile; do
141 sed -i $i -e "s|-I/nix/store/[^ ']*||g" -e "s|-L/nix/store/[^ ']*||g" -e "s|$TMPDIR|/no-such-path|g"
142 done
143
144 # Determinism: rebuild all bytecode
145 # We exclude lib2to3 because that's Python 2 code which fails
146 # We rebuild three times, once for each optimization level
147 find $out -name "*.py" | $out/bin/python -m compileall -q -f -x "lib2to3" -i -
148 find $out -name "*.py" | $out/bin/python -O -m compileall -q -f -x "lib2to3" -i -
149 find $out -name "*.py" | $out/bin/python -OO -m compileall -q -f -x "lib2to3" -i -
150 '';
151
152 passthru = let
153 pythonPackages = callPackage ../../../../../top-level/python-packages.nix {python=self; overrides=packageOverrides;};
154 in rec {
155 inherit libPrefix sitePackages x11Support;
156 executable = "${libPrefix}m";
157 buildEnv = callPackage ../../wrapper.nix { python = self; inherit (pythonPackages) requiredPythonModules; };
158 withPackages = import ../../with-packages.nix { inherit buildEnv pythonPackages;};
159 pkgs = pythonPackages;
160 isPy3 = true;
161 isPy35 = true;
162 interpreter = "${self}/bin/${executable}";
163 };
164
165 enableParallelBuilding = true;
166
167 meta = {
168 homepage = http://python.org;
169 description = "A high-level dynamically-typed programming language";
170 longDescription = ''
171 Python is a remarkably powerful dynamic programming language that
172 is used in a wide variety of application domains. Some of its key
173 distinguishing features include: clear, readable syntax; strong
174 introspection capabilities; intuitive object orientation; natural
175 expression of procedural code; full modularity, supporting
176 hierarchical packages; exception-based error handling; and very
177 high level dynamic data types.
178 '';
179 license = licenses.psfl;
180 platforms = with platforms; linux ++ darwin;
181 maintainers = with maintainers; [ fridh ];
182 };
183}