pyrox.dev
1{ lib, stdenv, fetch, cmake, python, llvm, libcxxabi, fixDarwinDylibNames, version }:
2
3stdenv.mkDerivation rec {
4 name = "libc++-${version}";
5
6 src = fetch "libcxx" "0k6cmjcxnp2pyl8xwy1wkyyckkmdrjddim94yf1gzjbjy9qi22jj";
7
8 postUnpack = ''
9 unpackFile ${libcxxabi.src}
10 export LIBCXXABI_INCLUDE_DIR="$PWD/$(ls -d libcxxabi-${version}*)/include"
11 '';
12
13 patches = [
14 # https://github.com/llvm-mirror/libcxx/commit/bcc92d75df0274b9593ebd097fcae60494e3bffc
15 ./pthread_mach_thread_np.patch
16 # glibc 2.26 fix
17 ./xlocale-glibc-2.26.patch
18 ] ++ stdenv.lib.optionals stdenv.hostPlatform.isMusl [
19 ../../libcxx-0001-musl-hacks.patch
20 ./max_align_t.patch
21 ];
22
23 prePatch = ''
24 substituteInPlace lib/CMakeLists.txt --replace "/usr/lib/libc++" "\''${LIBCXX_LIBCXXABI_LIB_PATH}/libc++"
25 '';
26
27 preConfigure = ''
28 # Get headers from the cxxabi source so we can see private headers not installed by the cxxabi package
29 cmakeFlagsArray=($cmakeFlagsArray -DLIBCXX_CXX_ABI_INCLUDE_PATHS="$LIBCXXABI_INCLUDE_DIR")
30 '' + lib.optionalString stdenv.hostPlatform.isMusl ''
31 patchShebangs utils/cat_files.py
32 '';
33 nativeBuildInputs = [ cmake ] ++ stdenv.lib.optional stdenv.hostPlatform.isMusl python;
34
35 buildInputs = [ libcxxabi ] ++ lib.optional stdenv.isDarwin fixDarwinDylibNames;
36
37 cmakeFlags = [
38 "-DLIBCXX_LIBCXXABI_LIB_PATH=${libcxxabi}/lib"
39 "-DLIBCXX_LIBCPPABI_VERSION=2"
40 "-DLIBCXX_CXX_ABI=libcxxabi"
41 ] ++ stdenv.lib.optional stdenv.hostPlatform.isMusl "-DLIBCXX_HAS_MUSL_LIBC=1";
42
43 enableParallelBuilding = true;
44
45 linkCxxAbi = stdenv.isLinux;
46
47 setupHook = ./setup-hook.sh;
48
49 meta = {
50 homepage = http://libcxx.llvm.org/;
51 description = "A new implementation of the C++ standard library, targeting C++11";
52 license = with stdenv.lib.licenses; [ ncsa mit ];
53 platforms = stdenv.lib.platforms.unix;
54 };
55}