pyrox.dev
1{ stdenv, fetchurl, gmp
2, withEmacsSupport ? true
3, withContrib ? true }:
4
5let
6 versionPkg = "0.3.7" ;
7
8 contrib = fetchurl {
9 url = "mirror://sourceforge/ats2-lang/ATS2-Postiats-contrib-${versionPkg}.tgz" ;
10 sha256 = "1w59ir9ij5bvvnxj6fb1rvzycfqa57i31wmpwawxbsb10bqwzyr6";
11 };
12
13 postInstallContrib = stdenv.lib.optionalString withContrib
14 ''
15 local contribDir=$out/lib/ats2-postiats-*/ ;
16 mkdir -p $contribDir ;
17 tar -xzf "${contrib}" --strip-components 1 -C $contribDir ;
18 '';
19
20 postInstallEmacs = stdenv.lib.optionalString withEmacsSupport
21 ''
22 local siteLispDir=$out/share/emacs/site-lisp/ats2 ;
23 mkdir -p $siteLispDir ;
24 install -m 0644 -v ./utils/emacs/*.el $siteLispDir ;
25 '';
26in
27
28stdenv.mkDerivation rec {
29 name = "ats2-${version}";
30 version = versionPkg;
31
32 src = fetchurl {
33 url = "mirror://sourceforge/ats2-lang/ATS2-Postiats-${version}.tgz";
34 sha256 = "19nxyi39fn42sp38kl14a6pvbxq9wr8y405wx0zz7mqb77r0m0h5";
35 };
36
37 buildInputs = [ gmp ];
38
39 setupHook = with stdenv.lib;
40 let
41 hookFiles =
42 [ ./setup-hook.sh ]
43 ++ optional withContrib ./setup-contrib-hook.sh;
44 in
45 builtins.toFile "setupHook.sh"
46 (concatMapStringsSep "\n" builtins.readFile hookFiles);
47
48 postInstall = postInstallContrib + postInstallEmacs;
49
50 meta = with stdenv.lib; {
51 description = "Functional programming language with dependent types";
52 homepage = "http://www.ats-lang.org";
53 license = licenses.gpl3Plus;
54 platforms = platforms.linux;
55 maintainers = with maintainers; [ thoughtpolice ttuegel ];
56 };
57}