pyrox.dev
lol
1{ stdenv, fetchurl, cabextract }:
2
3let
4
5 fonts = [
6 {name = "andale"; sha256 = "0w7927hlwayqf3vvanf8f3qp2g1i404jzqvhp1z3mp0sjm1gw905";}
7 {name = "arial"; sha256 = "1xkqyivbyb3z9dcalzidf8m4npzfpls2g0kldyn8g73f2i6plac5";}
8 {name = "arialb"; sha256 = "1a60zqrg63kjnykh5hz7dbpzvx7lyivn3vbrp7jyv9d1nvzz09d4";}
9 {name = "comic"; sha256 = "0ki0rljjc1pxkbsxg515fwx15yc95bdyaksa3pjd89nyxzzg6vcw";}
10 {name = "courie"; sha256 = "111k3waxki9yyxpjwl2qrdkswvsd2dmvhbjmmrwyipam2s31sldv";}
11 {name = "georgi"; sha256 = "0083jcpd837j2c06kp1q8glfjn9k7z6vg3wi137savk0lv6psb1c";}
12 {name = "impact"; sha256 = "1yyc5z7zmm3s418hmrkmc8znc55afsrz5dgxblpn9n81fhxyyqb0";}
13 {name = "times"; sha256 = "1aq7z3l46vwgqljvq9zfgkii6aivy00z1529qbjkspggqrg5jmnv";}
14 {name = "trebuc"; sha256 = "1jfsgz80pvyqvpfpaiz5pd8zwlcn67rg2jgynjwf22sip2dhssas";}
15 {name = "webdin"; sha256 = "0nnp2znmnmx87ijq9zma0vl0hd46npx38p0cc6lgp00hpid5nnb4";}
16 {name = "verdan"; sha256 = "15mdbbfqbyp25a6ynik3rck3m3mg44plwrj79rwncc9nbqjn3jy1";}
17 {name = "wd97vwr"; sha256 = "1lmkh3zb6xv47k0z2mcwk3vk8jff9m845c9igxm14bbvs6k2c4gn";}
18 ];
19
20 eula = fetchurl {
21 url = http://corefonts.sourceforge.net/eula.htm;
22 sha256 = "1aqbcnl032g2hd7iy56cs022g47scb0jxxp3mm206x1yqc90vs1c";
23 };
24
25in
26
27stdenv.mkDerivation {
28 name = "corefonts-1";
29
30 exes = map ({name, sha256}: fetchurl {
31 url = "mirror://sourceforge/corefonts/${name}32.exe";
32 inherit sha256;
33 }) fonts;
34
35 nativeBuildInputs = [cabextract];
36
37 buildCommand = ''
38 for i in $exes; do
39 cabextract --lowercase $i
40 done
41
42 cabextract --lowercase viewer1.cab
43
44 fontDir=$out/share/fonts/truetype
45 mkdir -p $fontDir
46 cp *.ttf $fontDir
47
48 # Also put the EULA there to be on the safe side.
49 cp ${eula} $fontDir/eula.html
50
51 # Set up no-op font configs to override any aliases set up by
52 # other packages.
53 mkdir -p $out/etc/fonts/conf.d
54 for name in Andale-Mono Arial-Black Arial Comic-Sans-MS \
55 Courier-New Georgia Impact Times-New-Roman \
56 Trebuchet Verdana Webdings ; do
57 substitute ${./no-op.conf} $out/etc/fonts/conf.d/30-''${name,,}.conf \
58 --subst-var-by fontname "''${name//-/ }"
59 done
60 '';
61
62 outputHashAlgo = "sha256";
63 outputHashMode = "recursive";
64 outputHash = "0baadsrgpqj15fgjmcn0aim0k0nk7mvivcxinw1zwg61kkcwhalx";
65
66 meta = with stdenv.lib; {
67 homepage = http://corefonts.sourceforge.net/;
68 description = "Microsoft's TrueType core fonts for the Web";
69 platforms = platforms.all;
70 license = licenses.unfreeRedistributable;
71 # Set a non-zero priority to allow easy overriding of the
72 # fontconfig configuration files.
73 priority = 5;
74 };
75}