pyrox.dev
fork
Configure Feed
Select the types of activity you want to include in your feed.
lol
fork
Configure Feed
Select the types of activity you want to include in your feed.
1{ lib
2, fetchFromGitHub
3, python
4, transmission
5, deluge
6, config
7}:
8
9with python.pkgs;
10
11buildPythonApplication rec {
12 version = "2.10.82";
13 name = "FlexGet-${version}";
14
15 src = fetchFromGitHub {
16 owner = "Flexget";
17 repo = "Flexget";
18 rev = version;
19 sha256 = "15508ihswfjbkzhf1f0qhn2ar1aiibz2ggp5d6r33icy8xwhpv09";
20 };
21
22 doCheck = true;
23 # test_regexp requires that HOME exist, test_filesystem requires a
24 # unicode-capable filesystem (and setting LC_ALL doesn't work).
25 # setlocale: LC_ALL: cannot change locale (en_US.UTF-8)
26 postPatch = ''
27 substituteInPlace requirements.txt \
28 --replace "chardet==3.0.3" "chardet" \
29 --replace "rebulk==0.8.2" "rebulk" \
30 --replace "cherrypy==10.2.2" "cherrypy" \
31 --replace "portend==1.8" "portend" \
32 --replace "sqlalchemy==1.1.10" "sqlalchemy" \
33 --replace "zxcvbn-python==4.4.15" "zxcvbn-python" \
34 --replace "flask-cors==3.0.2" "flask-cors" \
35 --replace "certifi==2017.4.17" "certifi" \
36 --replace "apscheduler==3.3.1" "apscheduler" \
37 --replace "path.py==10.3.1" "path.py" \
38 --replace "tempora==1.8" "tempora" \
39 --replace "cheroot==5.5.0" "cheroot" \
40 --replace "six==1.10.0" "six" \
41 --replace "aniso8601==1.2.1" "aniso8601"
42 '';
43
44 checkPhase = ''
45 export HOME=.
46 py.test --disable-pytest-warnings -k "not test_quality_failures \
47 and not test_group_quality \
48 and not crash_report \
49 and not test_multi_episode \
50 and not test_double_episodes \
51 and not test_inject_force \
52 and not test_double_prefered \
53 and not test_double \
54 and not test_non_ascii"
55 '';
56
57 buildInputs = [ pytest mock vcrpy pytest-catchlog boto3 ];
58 propagatedBuildInputs = [
59 feedparser sqlalchemy pyyaml chardet
60 beautifulsoup4 html5lib PyRSS2Gen pynzb
61 rpyc jinja2 jsonschema requests dateutil jsonschema
62 pathpy guessit_2_0 APScheduler
63 terminaltables colorclass
64 cherrypy flask flask-restful flask-restplus
65 flask-compress flask_login flask-cors
66 pyparsing safe future zxcvbn-python
67 werkzeug tempora cheroot rebulk portend
68 ] ++ lib.optional (pythonOlder "3.4") pathlib
69 # enable deluge and transmission plugin support, if they're installed
70 ++ lib.optional (config.deluge or false) deluge
71 ++ lib.optional (transmission != null) transmissionrpc;
72
73 meta = {
74 homepage = https://flexget.com/;
75 description = "Multipurpose automation tool for content like torrents";
76 license = lib.licenses.mit;
77 maintainers = with lib.maintainers; [ domenkozar tari ];
78 broken = true; # as of 2018-02-09
79 };
80}