pyrox.dev
1{ stdenv, fetchFromGitHub, autoreconfHook, zlib, pkgconfig, libuuid }:
2
3stdenv.mkDerivation rec{
4 version = "1.5.0";
5 name = "netdata-${version}";
6
7 src = fetchFromGitHub {
8 rev = "v${version}";
9 owner = "firehol";
10 repo = "netdata";
11 sha256 = "1nsv0s11ai1kvig9xr4cz2f2lalvilpbfjpd8fdfqk9fak690zhz";
12 };
13
14 buildInputs = [ autoreconfHook zlib pkgconfig libuuid ];
15
16 # Allow UI to load when running as non-root
17 patches = [ ./web_access.patch ];
18
19 # Build will fail trying to create /var/{cache,lib,log}/netdata without this
20 postPatch = ''
21 sed -i '/dist_.*_DATA = \.keep/d' src/Makefile.am
22 '';
23
24 configureFlags = [
25 "--localstatedir=/var"
26 ];
27
28 # App fails on runtime if the default config file is not detected
29 # The upstream installer does prepare an empty file too
30 postInstall = ''
31 touch $out/etc/netdata/netdata.conf
32 '';
33
34 meta = with stdenv.lib; {
35 description = "Real-time performance monitoring tool";
36 homepage = http://netdata.firehol.org;
37 license = licenses.gpl3;
38 platforms = platforms.linux;
39 maintainers = [ maintainers.lethalman ];
40 };
41
42}