pyrox.dev
lol
1{ stdenv, fetchurl, tcl, tk, libX11, zlib, makeWrapper }:
2
3stdenv.mkDerivation rec {
4 name = "scid-${version}";
5 version = "4.3";
6
7 src = fetchurl {
8 url = "mirror://sourceforge/scid/scid-4.3.tar.bz2";
9 sha256 = "0zb5qp04x8w4gn2kvfdfq2p44kmzfcqn7v167dixz6nlyxg41hrw";
10 };
11
12 buildInputs = [ tcl tk libX11 zlib makeWrapper ];
13
14 prePatch = ''
15 sed -i -e '/^ *set headerPath *{/a ${tcl}/include ${tk}/include' \
16 -e '/^ *set libraryPath *{/a ${tcl}/lib ${tk}/lib' \
17 -e '/^ *set x11Path *{/a ${libX11}/lib/' \
18 configure
19
20 sed -i -e '/^ *set scidShareDir/s|\[file.*|"'"$out/share"'"|' \
21 tcl/config.tcl
22 '';
23
24 configureFlags = [
25 "BINDIR=$(out)/bin"
26 "SHAREDIR=$(out)/share"
27 ];
28
29 hardeningDisable = [ "format" ];
30
31 dontPatchShebangs = true;
32
33 postFixup = ''
34 for cmd in sc_addmove sc_eco sc_epgn scidpgn \
35 sc_import sc_spell sc_tree spliteco
36 do
37 sed -i -e '1c#!'"$out"'/bin/tcscid' "$out/bin/$cmd"
38 done
39
40 sed -i -e '1c#!${tcl}/bin/tcslsh' "$out/bin/spf2spi"
41 sed -i -e '1c#!${tk}/bin/wish' "$out/bin/sc_remote"
42 sed -i -e '1c#!'"$out"'/bin/tkscid' "$out/bin/scid"
43
44 for cmd in $out/bin/*
45 do
46 wrapProgram "$cmd" \
47 --set TCLLIBPATH "${tcl}/${tcl.libdir}" \
48 --set TK_LIBRARY "${tk}/lib/${tk.libPrefix}"
49 done
50 '';
51
52 meta = {
53 description = "Chess database with play and training functionality";
54 homepage = http://scid.sourceforge.net/;
55 license = stdenv.lib.licenses.gpl2;
56 };
57}