pyrox.dev
1{ stdenv, fetchurl
2, bzip2
3, expat
4, libffi
5, gdbm
6, lzma
7, ncurses
8, openssl
9, readline
10, sqlite
11, tcl ? null, tk ? null, tix ? null, libX11 ? null, xproto ? null, x11Support ? false
12, zlib
13, callPackage
14, self
15, CF, configd
16, python-setup-hook
17# For the Python package set
18, pkgs, packageOverrides ? (self: super: {})
19}:
20
21assert x11Support -> tcl != null
22 && tk != null
23 && xproto != null
24 && libX11 != null;
25
26with stdenv.lib;
27
28let
29 majorVersion = "3.4";
30 minorVersion = "7";
31 minorVersionSuffix = "";
32 pythonVersion = majorVersion;
33 version = "${majorVersion}.${minorVersion}${minorVersionSuffix}";
34 libPrefix = "python${majorVersion}";
35 sitePackages = "lib/${libPrefix}/site-packages";
36
37 buildInputs = filter (p: p != null) [
38 zlib bzip2 expat lzma libffi gdbm sqlite readline ncurses openssl ]
39 ++ optionals x11Support [ tcl tk libX11 xproto ]
40 ++ optionals stdenv.isDarwin [ CF configd ];
41
42in stdenv.mkDerivation {
43 name = "python3-${version}";
44 pythonVersion = majorVersion;
45 inherit majorVersion version;
46
47 inherit buildInputs;
48
49 src = fetchurl {
50 url = "http://www.python.org/ftp/python/${version}/Python-${version}.tar.xz";
51 sha256 = "06wx2ag0dnixny67jfdl5z10243fjga898cgxhnr4dnxaqmwy547";
52 };
53
54 NIX_LDFLAGS = optionalString stdenv.isLinux "-lgcc_s";
55
56 # Determinism: The interpreter is patched to write null timestamps when compiling python files.
57 # This way python doesn't try to update them when we freeze timestamps in nix store.
58 DETERMINISTIC_BUILD=1;
59 # Determinism: We fix the hashes of str, bytes and datetime objects.
60 PYTHONHASHSEED=0;
61
62 prePatch = optionalString stdenv.isDarwin ''
63 substituteInPlace configure --replace '`/usr/bin/arch`' '"i386"'
64 substituteInPlace configure --replace '-Wl,-stack_size,1000000' ' '
65 '';
66
67 patches = [
68 ./no-ldconfig.patch
69 ];
70
71 postPatch = ''
72 # Determinism
73 substituteInPlace "Lib/py_compile.py" --replace "source_stats['mtime']" "(1 if 'DETERMINISTIC_BUILD' in os.environ else source_stats['mtime'])"
74 # Determinism. This is done unconditionally
75 substituteInPlace "Lib/importlib/_bootstrap.py" --replace "source_mtime = int(source_stats['mtime'])" "source_mtime = 1"
76 '' + optionalString (x11Support && (tix != null)) ''
77 substituteInPlace "Lib/tkinter/tix.py" --replace "os.environ.get('TIX_LIBRARY')" "os.environ.get('TIX_LIBRARY') or '${tix}/lib'"
78 ''
79 # Avoid picking up getentropy() from glibc >= 2.25, as that would break
80 # on older kernels. http://bugs.python.org/issue29157
81 + optionalString stdenv.isLinux ''
82 substituteInPlace Python/random.c --replace 'defined(HAVE_GETENTROPY)' '0'
83 cat Python/random.c
84 '';
85
86 CPPFLAGS="${concatStringsSep " " (map (p: "-I${getDev p}/include") buildInputs)}";
87 LDFLAGS="${concatStringsSep " " (map (p: "-L${getLib p}/lib") buildInputs)}";
88 LIBS="${optionalString (!stdenv.isDarwin) "-lcrypt"} ${optionalString (ncurses != null) "-lncurses"}";
89
90 configureFlags = [
91 "--enable-shared"
92 "--with-threads"
93 "--without-ensurepip"
94 "--with-system-expat"
95 "--with-system-ffi"
96 ];
97
98 preConfigure = ''
99 for i in /usr /sw /opt /pkg; do # improve purity
100 substituteInPlace ./setup.py --replace $i /no-such-path
101 done
102 ${optionalString stdenv.isDarwin ''
103 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -msse2"
104 export MACOSX_DEPLOYMENT_TARGET=10.6
105 ''}
106 '';
107
108 setupHook = python-setup-hook sitePackages;
109
110 postInstall = ''
111 # needed for some packages, especially packages that backport functionality
112 # to 2.x from 3.x
113 for item in $out/lib/python${majorVersion}/test/*; do
114 if [[ "$item" != */test_support.py*
115 && "$item" != */test/support
116 && "$item" != */test/libregrtest
117 && "$item" != */test/regrtest.py* ]]; then
118 rm -rf "$item"
119 else
120 echo $item
121 fi
122 done
123 touch $out/lib/python${majorVersion}/test/__init__.py
124
125 ln -s "$out/include/python${majorVersion}m" "$out/include/python${majorVersion}"
126 paxmark E $out/bin/python${majorVersion}
127
128 # Python on Nix is not manylinux1 compatible. https://github.com/NixOS/nixpkgs/issues/18484
129 echo "manylinux1_compatible=False" >> $out/lib/${libPrefix}/_manylinux.py
130
131 # Determinism: Windows installers were not deterministic.
132 # We're also not interested in building Windows installers.
133 find "$out" -name 'wininst*.exe' | xargs -r rm -f
134
135 # Use Python3 as default python
136 ln -s "$out/bin/idle3" "$out/bin/idle"
137 ln -s "$out/bin/pydoc3" "$out/bin/pydoc"
138 ln -s "$out/bin/python3" "$out/bin/python"
139 ln -s "$out/bin/python3-config" "$out/bin/python-config"
140 ln -s "$out/lib/pkgconfig/python3.pc" "$out/lib/pkgconfig/python.pc"
141
142 # Get rid of retained dependencies on -dev packages, and remove
143 # some $TMPDIR references to improve binary reproducibility.
144 # Note that the .pyc file of _sysconfigdata.py should be regenerated!
145 for i in $out/lib/python${majorVersion}/_sysconfigdata.py $out/lib/python${majorVersion}/config-${majorVersion}m/Makefile; do
146 sed -i $i -e "s|-I/nix/store/[^ ']*||g" -e "s|-L/nix/store/[^ ']*||g" -e "s|$TMPDIR|/no-such-path|g"
147 done
148
149 # Determinism: rebuild all bytecode
150 # We exclude lib2to3 because that's Python 2 code which fails
151 # We rebuild three times, once for each optimization level
152 find $out -name "*.py" | $out/bin/python -m compileall -q -f -x "lib2to3" -i -
153 find $out -name "*.py" | $out/bin/python -O -m compileall -q -f -x "lib2to3" -i -
154 find $out -name "*.py" | $out/bin/python -OO -m compileall -q -f -x "lib2to3" -i -
155 '';
156
157 passthru = let
158 pythonPackages = callPackage ../../../../../top-level/python-packages.nix {python=self; overrides=packageOverrides;};
159 in rec {
160 inherit libPrefix sitePackages x11Support;
161 executable = "${libPrefix}m";
162 buildEnv = callPackage ../../wrapper.nix { python = self; };
163 withPackages = import ../../with-packages.nix { inherit buildEnv pythonPackages;};
164 pkgs = pythonPackages;
165 isPy3 = true;
166 isPy34 = true;
167 is_py3k = true; # deprecated
168 interpreter = "${self}/bin/${executable}";
169 };
170
171 enableParallelBuilding = true;
172
173 meta = {
174 homepage = http://python.org;
175 description = "A high-level dynamically-typed programming language";
176 longDescription = ''
177 Python is a remarkably powerful dynamic programming language that
178 is used in a wide variety of application domains. Some of its key
179 distinguishing features include: clear, readable syntax; strong
180 introspection capabilities; intuitive object orientation; natural
181 expression of procedural code; full modularity, supporting
182 hierarchical packages; exception-based error handling; and very
183 high level dynamic data types.
184 '';
185 license = licenses.psfl;
186 platforms = with platforms; linux ++ darwin;
187 maintainers = with maintainers; [ chaoflow domenkozar cstrahan ];
188 };
189}