pyrox.dev
1{ stdenv, fetchgit, fetchurl, python2, makeWrapper, pkgconfig, gcc,
2 pypy, libffi, libedit, libuv, boost, zlib,
3 variant ? "jit", buildWithPypy ? false }:
4
5let
6 commit-count = "1356";
7 common-flags = "--thread --gcrootfinder=shadowstack --continuation";
8 variants = {
9 jit = { flags = "--opt=jit"; target = "target.py"; };
10 jit-preload = { flags = "--opt=jit"; target = "target_preload.py"; };
11 no-jit = { flags = ""; target = "target.py"; };
12 no-jit-preload = { flags = ""; target = "target_preload.py"; };
13 };
14 pixie-src = fetchgit {
15 url = "https://github.com/pixie-lang/pixie.git";
16 rev = "d2a4267ea088f711af36a74928e8dfd8360584ad";
17 sha256 = "1asf6yx7zy9cx4bsg8iai57dy3r3m45xcmkmw2vix70xvfy23ryf";
18 };
19 pypy-tag = "91db1a9";
20 pypy-src = fetchurl {
21 name = "pypy-src-${pypy-tag}";
22 url = "https://bitbucket.org/pypy/pypy/get/${pypy-tag}.tar.bz2";
23 sha256 = "0ylbqvhbcp5m09l15i2q2h3a0vjd055x2r37cq71lkhgmmaxrwbq";
24 };
25 libs = [ libffi libedit libuv boost.dev boost.out zlib ];
26 include-path = stdenv.lib.concatStringsSep ":"
27 (map (p: "${p}/include") libs);
28 library-path = stdenv.lib.concatStringsSep ":"
29 (map (p: "${p}/lib") libs);
30 bin-path = stdenv.lib.concatStringsSep ":"
31 (map (p: "${p}/bin") [ gcc ]);
32 build = {flags, target}: stdenv.mkDerivation rec {
33 name = "pixie-${version}";
34 version = "0-r${commit-count}-${variant}";
35 nativeBuildInputs = libs;
36 buildInputs = [ pkgconfig makeWrapper ];
37 PYTHON = if buildWithPypy
38 then "${pypy}/pypy-c/.pypy-c-wrapped"
39 else "${python2.interpreter}";
40 unpackPhase = ''
41 cp -R ${pixie-src} pixie-src
42 mkdir pypy-src
43 (cd pypy-src
44 tar --strip-components=1 -xjf ${pypy-src})
45 chmod -R +w pypy-src pixie-src
46 '';
47 patchPhase = ''
48 (cd pixie-src
49 patch -p1 < ${./load_paths.patch}
50 libraryPaths='["${libuv}" "${libedit}" "${libffi.dev}" "${boost.dev}" "${boost.out}" "${zlib.dev}"]'
51 export libraryPaths
52 substituteAllInPlace ./pixie/ffi-infer.pxi)
53 '';
54 buildPhase = ''(
55 PYTHONPATH="`pwd`/pypy-src:$PYTHONPATH";
56 RPYTHON="`pwd`/pypy-src/rpython/bin/rpython";
57 cd pixie-src
58 $PYTHON $RPYTHON ${common-flags} ${target}
59 export LD_LIBRARY_PATH="${library-path}:$LD_LIBRARY_PATH"
60 find pixie -name "*.pxi" -exec ./pixie-vm -c {} \;
61 )'';
62 installPhase = ''
63 mkdir -p $out/share $out/bin
64 cp pixie-src/pixie-vm $out/share/pixie-vm
65 cp -R pixie-src/pixie $out/share/pixie
66 makeWrapper $out/share/pixie-vm $out/bin/pixie-vm \
67 --prefix LD_LIBRARY_PATH : ${library-path} \
68 --prefix C_INCLUDE_PATH : ${include-path} \
69 --prefix LIBRARY_PATH : ${library-path} \
70 --prefix PATH : ${bin-path}
71 cat > $out/bin/pxi <<EOF
72 #!$shell
73 >&2 echo "[\$\$] WARNING: 'pxi' is a deprecated alias for 'pixie-vm', please update your scripts."
74 exec $out/bin/pixie-vm "\$@"
75 EOF
76 chmod +x $out/bin/pxi
77 '';
78 meta = {
79 description = "A clojure-like lisp, built with the pypy vm toolkit";
80 homepage = https://github.com/pixie-lang/pixie;
81 license = stdenv.lib.licenses.lgpl3;
82 platforms = ["x86_64-linux" "i686-linux"];
83 };
84 };
85in build (builtins.getAttr variant variants)