pyrox.dev
lol
1{ stdenv, fetchurl, gmp
2, withEmacsSupport ? true
3, withContrib ? true }:
4
5let
6 versionPkg = "0.3.0" ;
7
8 contrib = fetchurl {
9 url = "mirror://sourceforge/ats2-lang/ATS2-Postiats-contrib-${versionPkg}.tgz" ;
10 sha256 = "1s4yscisn9gsr692jmh4y5mz03012pv84cm7l5n51v83wc08fks0" ;
11 };
12
13 postInstallContrib = stdenv.lib.optionalString withContrib
14 ''
15 local contribDir=$out/lib/ats2-postiats-*/ ;
16 mkdir -p $contribDir ;
17 tar -xzf "${contrib}" --strip-components 1 -C $contribDir ;
18 '';
19
20 postInstallEmacs = stdenv.lib.optionalString withEmacsSupport
21 ''
22 local siteLispDir=$out/share/emacs/site-lisp/ats2 ;
23 mkdir -p $siteLispDir ;
24 install -m 0644 -v ./utils/emacs/*.el $siteLispDir ;
25 '';
26in
27
28stdenv.mkDerivation rec {
29 name = "ats2-${version}";
30 version = versionPkg;
31
32 src = fetchurl {
33 url = "mirror://sourceforge/ats2-lang/ATS2-Postiats-${version}.tgz";
34 sha256 = "1knf03r8a5sis7n8rw54flf1lxfbr3prywxb1czcdp6hsbcd1v1d";
35 };
36
37 patches = [ ./install-postiats-contrib.patch ];
38
39 buildInputs = [ gmp ];
40
41 setupHook = with stdenv.lib;
42 let
43 hookFiles =
44 [ ./setup-hook.sh ]
45 ++ optional withContrib ./setup-contrib-hook.sh;
46 in
47 builtins.toFile "setupHook.sh"
48 (concatMapStringsSep "\n" builtins.readFile hookFiles);
49
50 postInstall = postInstallContrib + postInstallEmacs;
51
52 meta = with stdenv.lib; {
53 description = "Functional programming language with dependent types";
54 homepage = "http://www.ats-lang.org";
55 license = licenses.gpl3Plus;
56 platforms = platforms.linux;
57 maintainers = with maintainers; [ thoughtpolice ttuegel ];
58 };
59}