pyrox.dev
lol
1{ stdenv, fetchurl, groff }:
2
3assert stdenv.isLinux;
4
5stdenv.mkDerivation rec {
6 name = "mdadm-3.3.4";
7
8 src = fetchurl {
9 url = "mirror://kernel/linux/utils/raid/mdadm/${name}.tar.xz";
10 sha256 = "0s6a4bq7v7zxiqzv6wn06fv9f6g502dp047lj471jwxq0r9z9rca";
11 };
12
13 # This is to avoid self-references, which causes the initrd to explode
14 # in size and in turn prevents mdraid systems from booting.
15 allowedReferences = [ stdenv.glibc.out ];
16
17 patches = [ ./no-self-references.patch ];
18
19 makeFlags = [
20 "NIXOS=1" "INSTALL=install" "INSTALL_BINDIR=$(out)/sbin"
21 "MANDIR=$(out)/share/man" "RUN_DIR=/dev/.mdadm"
22 ] ++ stdenv.lib.optionals (stdenv ? cross) [
23 "CROSS_COMPILE=${stdenv.cross.config}-"
24 ];
25
26 nativeBuildInputs = [ groff ];
27
28 # Attempt removing if building with gcc5 when updating
29 NIX_CFLAGS_COMPILE = "-std=gnu89";
30
31 preConfigure = ''
32 sed -e 's@/lib/udev@''${out}/lib/udev@' \
33 -e 's@ -Werror @ @' \
34 -e 's@/usr/sbin/sendmail@/var/setuid-wrappers/sendmail@' -i Makefile
35 '';
36
37 meta = {
38 description = "Programs for managing RAID arrays under Linux";
39 homepage = http://neil.brown.name/blog/mdadm;
40 platforms = stdenv.lib.platforms.linux;
41 };
42}