pyrox.dev
1{ stdenv, lib, fetchurl, buildPythonPackage, python, smpeg, libX11
2, SDL, SDL_image, SDL_mixer, SDL_ttf, libpng, libjpeg, portmidi, isPy3k,
3}:
4
5buildPythonPackage rec {
6 name = "pygame-${version}";
7 version = "1.9.1";
8
9 src = fetchurl {
10 url = "http://www.pygame.org/ftp/pygame-1.9.1release.tar.gz";
11 sha256 = "0cyl0ww4fjlf289pjxa53q4klyn55ajvkgymw0qrdgp4593raq52";
12 };
13
14 buildInputs = [
15 SDL SDL_image SDL_mixer SDL_ttf libpng libjpeg
16 smpeg portmidi libX11
17 ];
18
19 # http://ubuntuforums.org/showthread.php?t=1960262
20 disabled = isPy3k;
21
22 # Tests fail because of no audio device and display.
23 doCheck = false;
24
25 patches = [ ./pygame-v4l.patch ];
26
27 preConfigure = ''
28 sed \
29 -e "s/^origincdirs = .*/origincdirs = []/" \
30 -e "s/^origlibdirs = .*/origlibdirs = []/" \
31 -e "/\/include\/smpeg/d" \
32 -i config_unix.py
33 ${lib.concatMapStrings (dep: ''
34 sed \
35 -e "/^origincdirs =/aorigincdirs += ['${lib.getDev dep}/include']" \
36 -e "/^origlibdirs =/aoriglibdirs += ['${lib.getLib dep}/lib']" \
37 -i config_unix.py
38 '') buildInputs
39 }
40 LOCALBASE=/ ${python.interpreter} config.py
41 '';
42
43 meta = with stdenv.lib; {
44 description = "Python library for games";
45 homepage = "http://www.pygame.org/";
46 license = licenses.lgpl21Plus;
47 platforms = platforms.linux;
48 };
49}