pyrox.dev
1{ lib, stdenv, fetchurl, interactive ? false, readline ? null, ncurses ? null }:
2
3assert interactive -> readline != null && ncurses != null;
4
5stdenv.mkDerivation {
6 name = "sqlite-3.14.1";
7
8 src = fetchurl {
9 url = "http://sqlite.org/2016/sqlite-autoconf-3140100.tar.gz";
10 sha256 = "19j73j44akqgc6m82wm98yvnmm3mfzmfqr8mp3n7n080d53q4wdw";
11 };
12
13 outputs = [ "bin" "dev" "out" ];
14
15 buildInputs = lib.optionals interactive [ readline ncurses ];
16
17 configureFlags = [ "--enable-threadsafe" ] ++ lib.optional interactive "--enable-readline";
18
19 NIX_CFLAGS_COMPILE = [
20 "-DSQLITE_ENABLE_COLUMN_METADATA"
21 "-DSQLITE_ENABLE_DBSTAT_VTAB"
22 "-DSQLITE_ENABLE_JSON1"
23 "-DSQLITE_ENABLE_FTS3"
24 "-DSQLITE_ENABLE_FTS3_PARENTHESIS"
25 "-DSQLITE_ENABLE_FTS3_TOKENIZER"
26 "-DSQLITE_ENABLE_FTS4"
27 "-DSQLITE_ENABLE_RTREE"
28 "-DSQLITE_ENABLE_STMT_SCANSTATUS"
29 "-DSQLITE_ENABLE_UNLOCK_NOTIFY"
30 "-DSQLITE_SOUNDEX"
31 "-DSQLITE_SECURE_DELETE"
32 ];
33
34 # Test for features which may not be available at compile time
35 preBuild = ''
36 # Use pread(), pread64(), pwrite(), pwrite64() functions for better performance if they are available.
37 if cc -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread_pwrite_test" <<< \
38 ''$'#include <unistd.h>\nint main()\n{\n pread(0, NULL, 0, 0);\n pwrite(0, NULL, 0, 0);\n return 0;\n}'; then
39 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD"
40 fi
41 if cc -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread64_pwrite64_test" <<< \
42 ''$'#include <unistd.h>\nint main()\n{\n pread64(0, NULL, 0, 0);\n pwrite64(0, NULL, 0, 0);\n return 0;\n}'; then
43 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD64"
44 elif cc -D_LARGEFILE64_SOURCE -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread64_pwrite64_test" <<< \
45 ''$'#include <unistd.h>\nint main()\n{\n pread64(0, NULL, 0, 0);\n pwrite64(0, NULL, 0, 0);\n return 0;\n}'; then
46 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD64 -D_LARGEFILE64_SOURCE"
47 fi
48
49 echo ""
50 echo "NIX_CFLAGS_COMPILE = $NIX_CFLAGS_COMPILE"
51 echo ""
52 '';
53
54 meta = {
55 homepage = http://www.sqlite.org/;
56 description = "A self-contained, serverless, zero-configuration, transactional SQL database engine";
57 platforms = stdenv.lib.platforms.unix;
58 maintainers = with stdenv.lib.maintainers; [ eelco np ];
59 };
60}