pyrox.dev
1{ stdenv, lib, fetchurl, unzip, jdk, pkgconfig, gtk
2, libXtst, libXi, mesa, webkit, libsoup, xorg
3, pango, gdk_pixbuf, glib
4}:
5
6let
7 platformMap = {
8 "x86_64-linux" =
9 { platform = "gtk-linux-x86_64";
10 sha256 = "0hq48zfqx2p0fqr0rlabnz2pdj0874k19918a4dbj0fhzkhrh959"; };
11 "i686-linux" =
12 { platform = "gtk-linux-x86";
13 sha256 = "10si8kmc7c9qmbpzs76609wkfb784pln3qpmra73gb3fbk7z8caf"; };
14 "x86_64-darwin" =
15 { platform = "cocoa-macosx-x86_64";
16 sha256 = "1565gg63ssrl04fh355vf9mnmq8qwwki3zpc3ybm7bylgkfwc9h4"; };
17 };
18
19 metadata = assert platformMap ? ${stdenv.system}; platformMap.${stdenv.system};
20
21in stdenv.mkDerivation rec {
22 version = "3.7.2";
23 fullVersion = "${version}-201202080800";
24 name = "swt-${version}";
25
26 hardeningDisable = [ "format" ];
27
28 # Alas, the Eclipse Project apparently doesn't produce source-only
29 # releases of SWT. So we just grab a binary release and extract
30 # "src.zip" from that.
31 src = fetchurl {
32 url = "http://archive.eclipse.org/eclipse/downloads/drops/R-${fullVersion}/${name}-${metadata.platform}.zip";
33 sha256 = metadata.sha256;
34 };
35
36 sourceRoot = ".";
37
38 buildInputs = [ unzip jdk pkgconfig gtk libXtst libXi mesa webkit libsoup ];
39
40 NIX_LFLAGS = (map (x: "-L${lib.getLib x}/lib") [ xorg.libX11 pango gdk_pixbuf glib ]) ++
41 [ "-lX11" "-lpango-1.0" "-lgdk_pixbuf-2.0" "-lglib-2.0" ];
42
43 buildPhase = ''
44 unzip src.zip -d src
45
46 cd src
47 sed -i "s#^LFLAGS =#LFLAGS = $NIX_LFLAGS #g" *.mak
48 export JAVA_HOME=${jdk}
49
50 sh ./build.sh
51
52 mkdir out
53 javac -d out/ $(find org/ -name "*.java")
54 '';
55
56 installPhase = ''
57 mkdir -p $out/lib
58 cp *.so $out/lib
59
60 mkdir -p $out/jars
61 cp version.txt out/
62 cd out && jar -c * > $out/jars/swt.jar
63 '';
64
65 meta = with stdenv.lib; {
66 homepage = http://www.eclipse.org/swt/;
67 description = "An widget toolkit for Java to access the user-interface facilities of the operating systems on which it is implemented";
68 license = licenses.epl10;
69 maintainers = with maintainers; [ pSub ];
70 platforms = with platforms; linux;
71 };
72}