pyrox.dev
1{ stdenv, fetchurl, mesa_glu, xlibsWrapper, libXmu, libXi }:
2
3with stdenv.lib;
4
5stdenv.mkDerivation rec {
6 name = "glew-1.13.0";
7
8 src = fetchurl {
9 url = "mirror://sourceforge/glew/${name}.tgz";
10 sha256 = "1iwb2a6wfhkzv6fa7zx2gz1lkwa0iwnd9ka1im5vdc44xm4dq9da";
11 };
12
13 outputs = [ "bin" "out" "dev" "doc" ];
14
15 nativeBuildInputs = [ xlibsWrapper libXmu libXi ];
16 propagatedNativeBuildInputs = [ mesa_glu ]; # GL/glew.h includes GL/glu.h
17
18 patchPhase = ''
19 sed -i 's|lib64|lib|' config/Makefile.linux
20 ${optionalString (stdenv ? cross) ''
21 sed -i -e 's/\(INSTALL.*\)-s/\1/' Makefile
22 ''}
23 '';
24
25 buildFlags = [ "all" ];
26 installFlags = [ "install.all" ];
27
28 preInstall = ''
29 makeFlagsArray+=(GLEW_DEST=$out BINDIR=$bin/bin INCDIR=$dev/include/GL)
30 '';
31
32 postInstall = ''
33 mkdir -pv $out/share/doc/glew
34 mkdir -p $out/lib/pkgconfig
35 cp glew*.pc $out/lib/pkgconfig
36 cp -r README.txt LICENSE.txt doc $out/share/doc/glew
37 rm $out/lib/*.a
38 '';
39
40 crossAttrs.makeFlags = [
41 "CC=${stdenv.cross.config}-gcc"
42 "LD=${stdenv.cross.config}-gcc"
43 "AR=${stdenv.cross.config}-ar"
44 "STRIP="
45 ] ++ optional (stdenv.cross.libc == "msvcrt") "SYSTEM=mingw"
46 ++ optional (stdenv.cross.libc == "libSystem") "SYSTEM=darwin";
47
48 meta = with stdenv.lib; {
49 description = "An OpenGL extension loading library for C(++)";
50 homepage = http://glew.sourceforge.net/;
51 license = licenses.free; # different files under different licenses
52 #["BSD" "GLX" "SGI-B" "GPL2"]
53 platforms = platforms.mesaPlatforms;
54 };
55}