pyrox.dev
1{ stdenv, fetchurl, fetchpatch, pkgconfig, audiofile, libcap
2, openglSupport ? false, mesa_noglu
3, alsaSupport ? true, alsaLib
4, x11Support ? true, libXext, libICE, libXrandr
5, pulseaudioSupport ? true, libpulseaudio
6, OpenGL, CoreAudio, CoreServices, AudioUnit, Kernel, Cocoa
7}:
8
9# OSS is no longer supported, for it's much crappier than ALSA and
10# PulseAudio.
11assert (stdenv.isLinux && !(stdenv ? cross)) -> alsaSupport || pulseaudioSupport;
12
13let
14 inherit (stdenv.lib) optional optionals;
15in
16stdenv.mkDerivation rec {
17 name = "SDL-${version}";
18 version = "1.2.15";
19
20 src = fetchurl {
21 url = "http://www.libsdl.org/release/${name}.tar.gz";
22 sha256 = "005d993xcac8236fpvd1iawkz4wqjybkpn8dbwaliqz5jfkidlyn";
23 };
24
25 outputs = [ "out" "dev" ];
26 outputBin = "dev"; # sdl-config
27
28 nativeBuildInputs = [ pkgconfig ];
29
30 # Since `libpulse*.la' contain `-lgdbm', PulseAudio must be propagated.
31 propagatedBuildInputs =
32 optionals x11Support [ libXext libICE libXrandr ] ++
33 optional alsaSupport alsaLib ++
34 optional stdenv.isLinux libcap ++
35 optional openglSupport mesa_noglu ++
36 optional pulseaudioSupport libpulseaudio ++
37 optional stdenv.isDarwin Cocoa;
38
39 buildInputs = let
40 notMingw = !(stdenv ? cross) || stdenv.cross.libc != "msvcrt";
41 in optional notMingw audiofile
42 ++ optionals stdenv.isDarwin [ OpenGL CoreAudio CoreServices AudioUnit Kernel ];
43
44 # XXX: By default, SDL wants to dlopen() PulseAudio, in which case
45 # we must arrange to add it to its RPATH; however, `patchelf' seems
46 # to fail at doing this, hence `--disable-pulseaudio-shared'.
47 configureFlags = [
48 "--disable-oss"
49 "--disable-video-x11-xme"
50 "--disable-x11-shared"
51 "--disable-alsa-shared"
52 "--enable-rpath"
53 "--disable-pulseaudio-shared"
54 "--disable-osmesa-shared"
55 ] ++ optionals (stdenv ? cross) ([
56 "--without-x"
57 ] ++ optional alsaSupport "--with-alsa-prefix=${alsaLib.out}/lib");
58
59 patches = [
60 # Fix window resizing issues, e.g. for xmonad
61 # Ticket: http://bugzilla.libsdl.org/show_bug.cgi?id=1430
62 (fetchpatch {
63 name = "fix_window_resizing.diff";
64 url = "https://bugs.debian.org/cgi-bin/bugreport.cgi?msg=10;filename=fix_window_resizing.diff;att=2;bug=665779";
65 sha256 = "1z35azc73vvi19pzi6byck31132a8w1vzrghp1x3hy4a4f9z4gc6";
66 })
67 # Fix drops of keyboard events for SDL_EnableUNICODE
68 (fetchpatch {
69 url = "http://hg.libsdl.org/SDL/raw-rev/0aade9c0203f";
70 sha256 = "1y9izncjlqvk1mkz1pkl9lrk9s452cmg2izjjlqqrhbn8279xy50";
71 })
72 # Ignore insane joystick axis events
73 (fetchpatch {
74 url = "http://hg.libsdl.org/SDL/raw-rev/95abff7adcc2";
75 sha256 = "0i8x0kx0pw12ld5bfxhyzs466y3c0n9dscw1ijhq1b96r72xyhqq";
76 })
77 # Workaround X11 bug to allow changing gamma
78 # Ticket: https://bugs.freedesktop.org/show_bug.cgi?id=27222
79 (fetchpatch {
80 url = "http://pkgs.fedoraproject.org/cgit/rpms/SDL.git/plain/SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch?id=04a3a7b1bd88c2d5502292fad27e0e02d084698d";
81 sha256 = "0x52s4328kilyq43i7psqkqg7chsfwh0aawr50j566nzd7j51dlv";
82 })
83 # Fix a build failure on OS X Mavericks
84 # Ticket: https://bugzilla.libsdl.org/show_bug.cgi?id=2085
85 (fetchpatch {
86 url = "http://hg.libsdl.org/SDL/raw-rev/e9466ead70e5";
87 sha256 = "0mpwdi09h89df2wxqw87m1rdz7pr46k0w6alk691k8kwv970z6pl";
88 })
89 (fetchpatch {
90 url = "http://hg.libsdl.org/SDL/raw-rev/bbfb41c13a87";
91 sha256 = "1336g7waaf1c8yhkz11xbs500h8bmvabh4h437ax8l1xdwcppfxv";
92 })
93 ./find-headers.patch
94 ];
95
96 postFixup = ''moveToOutput share/aclocal "$dev" '';
97
98 setupHook = ./setup-hook.sh;
99
100 passthru = { inherit openglSupport; };
101
102 meta = with stdenv.lib; {
103 description = "A cross-platform multimedia library";
104 homepage = "http://www.libsdl.org/";
105 maintainers = with maintainers; [ lovek323 ];
106 platforms = platforms.unix;
107 license = licenses.lgpl21;
108 };
109}