pyrox.dev
lol
1{ stdenv, fetchurl, perl, gnum4, ncurses, openssl
2, makeWrapper, gnused, gawk
3, wxSupport ? false, mesa ? null, wxGTK ? null, xlibs ? null }:
4
5assert wxSupport -> mesa != null && wxGTK != null && xlibs != null;
6
7let version = "15B03"; in
8
9stdenv.mkDerivation {
10 name = "erlang-" + version;
11
12 src = fetchurl {
13 url = "http://www.erlang.org/download/otp_src_R15B03-1.tar.gz";
14 sha256 = "4bccac86dd76aec050252e44276a0283a0df9218e6470cf042a9b9f9dfc9476c";
15 };
16
17 buildInputs =
18 [ perl gnum4 ncurses openssl
19 makeWrapper
20 ] ++ stdenv.lib.optional wxSupport [ mesa wxGTK xlibs.libX11 ];
21
22 patchPhase = '' sed -i "s@/bin/rm@rm@" lib/odbc/configure erts/configure '';
23
24 preConfigure = ''
25 export HOME=$PWD/../
26 sed -e s@/bin/pwd@pwd@g -i otp_build
27 '';
28
29 configureFlags = "--with-ssl=${openssl}";
30
31 postInstall = let
32 manpages = fetchurl {
33 url = "http://www.erlang.org/download/otp_doc_man_R${version}.tar.gz";
34 sha256 = "0sqamzbd7qyz3klgl9vm1qvl0rhsfd1dx485pb0m2185qvw02nha";
35 };
36 in ''
37 tar xf "${manpages}" -C "$out/lib/erlang"
38 for i in "$out"/lib/erlang/man/man[0-9]/*.[0-9]; do
39 prefix="''${i%/*}"
40 ensureDir "$out/share/man/''${prefix##*/}"
41 ln -s "$i" "$out/share/man/''${prefix##*/}/''${i##*/}erl"
42 done
43 '';
44
45 # Some erlang bin/ scripts run sed and awk
46 postFixup = ''
47 wrapProgram $out/lib/erlang/bin/erl --prefix PATH ":" "${gnused}/bin/"
48 wrapProgram $out/lib/erlang/bin/start_erl --prefix PATH ":" "${gnused}/bin/:${gawk}/bin"
49 '';
50
51 meta = {
52 homepage = "http://www.erlang.org/";
53 description = "Programming language used for massively scalable soft real-time systems";
54
55 longDescription = ''
56 Erlang is a programming language used to build massively scalable
57 soft real-time systems with requirements on high availability.
58 Some of its uses are in telecoms, banking, e-commerce, computer
59 telephony and instant messaging. Erlang's runtime system has
60 built-in support for concurrency, distribution and fault
61 tolerance.
62 '';
63
64 platforms = stdenv.lib.platforms.linux;
65 maintainers = [ stdenv.lib.maintainers.simons ];
66 };
67}