{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs =
    { flake-parts, ... }@inputs:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = inputs.nixpkgs.lib.systems.flakeExposed;

      perSystem =
        { pkgs, ... }:

        {
          devShells = {
            default = pkgs.mkShell {
              buildInputs = [
                pkgs.go
                pkgs.gofumpt
              ];
            };
          };

          packages = {
            default = pkgs.buildGoModule rec {
              pname = "record-dedup";
              version = "0.1.0";
              src = pkgs.nix-gitignore.gitignoreSource [ ] ./.;
              vendorHash = "sha256-++CZOfLxj7FRwixrB37edehX1Qh9e/hmrzeJdq+Vr/E=";
              ldflags = [
                "-s"
                "-w"
                "-X=main.Version=${version}"
              ];
              meta = {
                description = "Small tool to make it convenient to deduplicate records in collections";
                homepage = "https://tangled.org/karitham.dev/record-deduper";
                license = pkgs.lib.licenses.mit;
                mainProgram = "record-dedup";
              };
            };
          };
        };
    };
}