# SPDX-FileCopyrightText: © 2026 Jeffrey C. Ollie <jeff@ocjtech.us>
# SPDX-License-Identifier: MIT

{
  lib,
  stdenv,
  callPackage,
  zig_0_17,
}:
let
  # Generated from build.zig.zon by zon2nix; regenerate with
  #   nix develop -c zon2nix --17 --nix=build.zig.zon.nix build.zig.zon
  zigDeps = callPackage ./build.zig.zon.nix { };
in
stdenv.mkDerivation (finalAttrs: {
  pname = "zigurine";
  version = "0.1.0";

  src = lib.fileset.toSource {
    root = ./.;
    fileset = lib.fileset.unions [
      ./build.zig
      ./build.zig.zon
      ./src
      ./LICENSES
      ./README.md
    ];
  };

  # The setup hook ships inside the compiler package; it supplies the build,
  # check and install phases and builds ReleaseSafe for a baseline CPU.
  nativeBuildInputs = [ zig_0_17 ];

  zigBuildFlags = [
    "--system"
    "${zigDeps}"
  ];
  # The check phase assembles its own flags rather than reusing the build's,
  # so without this `zig build test` runs without --system, tries to fetch,
  # and fails in the sandbox.
  zigCheckFlags = finalAttrs.zigBuildFlags;

  doCheck = true;

  meta = {
    description = "A rainbow login banner drawn in a real font and shown with the kitty graphics protocol";
    homepage = "https://git.jcollie.dev/jeff/zigurine";
    license = lib.licenses.mit;
    mainProgram = "zigurine";
    platforms = lib.platforms.unix;
  };
})