Lumar / flake.nix

{
  description = "Lumar - Nix configuration selector TUI";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = nixpkgs.lib.genAttrs systems;
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.rustPlatform.buildRustPackage {
            pname = "lumar";
            version = "0.1.0";

            src = pkgs.lib.cleanSourceWith {
              src = ./.;
              filter = path: type:
                let baseName = baseNameOf (toString path);
                in pkgs.lib.cleanSourceFilter path type &&
                   !(builtins.elem baseName [ "target" ".devenv" ".jj" ]);
            };

            cargoLock = {
              lockFile = ./Cargo.lock;
              outputHashes = {
                # Run `nix build` once to get the correct hash from the error message,
                # then replace the placeholder below.
                "sly-0.0.2" = "sha256-GdkppkfYWSaBl9jgae90ST/sSHs2zxdm3DHmye4bCA8=";
              };
            };

            meta = with pkgs.lib; {
              description = "TUI for selecting and applying Nix configurations";
              mainProgram = "lumar";
            };
          };
        }
      );
    };
}