# Setup systemd services
[group('setup')]
setup-services:
    #!/usr/bin/env bash
    enable_services=(
        "atop.service"
        "atopacct.service"
        "atop-rotate.timer"
        "firewalld.service"
        "snapper-cleanup.timer"
        "snapper-timeline.timer"
        "tailscaled.service"
    )
    for svc in "${enable_services[@]}"; do
        if ! sudo systemctl is-active --quiet "$svc"; then
            sudo systemctl enable --now "$svc"
        fi
    done

# Setup XDG user dirs
[group('setup')]
setup-xdg-user-dirs:
    #!/usr/bin/env bash
    cat <<EOF | sudo tee /etc/xdg/user-dirs.defaults
    DESKTOP=Desktop
    DOWNLOAD=Downloads
    TEMPLATES=
    PUBLICSHARE=
    DOCUMENTS=Documents
    MUSIC=
    PICTURES=Pictures
    VIDEOS=
    EOF

    rm -fv "${HOME}/.config/user-dirs.dirs"
    for dir in "Desktop" "Documents" "Downloads" "Music" "Pictures" "Public" "Templates" "Videos"; do
        rm -rfv "${HOME}/${dir}"
    done
    xdg-user-dirs-update

# Setup hyperreal configs
[group('setup')]
setup-cli:
    #!/usr/bin/env bash
    set -euo pipefail

    DOTFILES_DIR="${HOME}/repos/tangled.org/hyperreal.bsky.moonshadow.dev/dotfiles"
    if [ ! -d "$DOTFILES_DIR" ]; then
    	echo "${DOTFILES_DIR} not found."
    	exit 1
    fi

    find "${DOTFILES_DIR}/config" -maxdepth 1 -mindepth 1 -exec ln -sf {} "${HOME}/.config" \;
    find "${DOTFILES_DIR}/zsh" -maxdepth 1 -mindepth 1 -exec ln -sf {} "${HOME}" \;

# vim: ts=4 sts=4 sw=4 et ft=just