eti.tf
forked from
tangled.org/core
Monorepo for Tangled
boltless.me
1{
2 nixpkgs,
3 system,
4 hostSystem,
5 self,
6}: let
7 envVar = name: let
8 var = builtins.getEnv name;
9 in
10 if var == ""
11 then throw "\$${name} must be defined, see https://docs.tangled.org/hacking-on-tangled.html#hacking-on-tangled for more details"
12 else var;
13 envVarOr = name: default: let
14 var = builtins.getEnv name;
15 in
16 if var != ""
17 then var
18 else default;
19
20 plcUrl = envVarOr "TANGLED_VM_PLC_URL" "https://plc.directory";
21 jetstream = envVarOr "TANGLED_VM_JETSTREAM_ENDPOINT" "wss://jetstream1.us-west.bsky.network/subscribe";
22in
23 nixpkgs.lib.nixosSystem {
24 inherit system;
25 modules = [
26 self.nixosModules.knot
27 self.nixosModules.spindle
28 self.nixosModules.knotmirror
29 ({
30 lib,
31 config,
32 pkgs,
33 ...
34 }: {
35 virtualisation.vmVariant.virtualisation = {
36 host.pkgs = import nixpkgs {system = hostSystem;};
37
38 graphics = false;
39 memorySize = 2048;
40 diskSize = 10 * 1024;
41 cores = 2;
42 forwardPorts = [
43 # ssh
44 {
45 from = "host";
46 host.port = 2222;
47 guest.port = 22;
48 }
49 # knot
50 {
51 from = "host";
52 host.port = 6444;
53 guest.port = 6444;
54 }
55 # spindle
56 {
57 from = "host";
58 host.port = 6555;
59 guest.port = 6555;
60 }
61 # knotmirror
62 {
63 from = "host";
64 host.port = 7007; # 7000 is deserved in macos for Airplay
65 guest.port = 7000;
66 }
67 # knotmirror-tap
68 {
69 from = "host";
70 host.port = 7480;
71 guest.port = 7480;
72 }
73 # knotmirror-admin
74 {
75 from = "host";
76 host.port = 7200;
77 guest.port = 7200;
78 }
79 ];
80 sharedDirectories = {
81 # We can't use the 9p mounts directly for most of these
82 # as SQLite is incompatible with them. So instead we
83 # mount the shared directories to a different location
84 # and copy the contents around on service start/stop.
85 knotData = {
86 source = "$TANGLED_VM_DATA_DIR/knot";
87 target = "/mnt/knot-data";
88 };
89 spindleData = {
90 source = "$TANGLED_VM_DATA_DIR/spindle";
91 target = "/mnt/spindle-data";
92 };
93 spindleLogs = {
94 source = "$TANGLED_VM_DATA_DIR/spindle-logs";
95 target = "/var/log/spindle";
96 };
97 };
98 };
99 # This is fine because any and all ports that are forwarded to host are explicitly marked above, we don't need a separate guest firewall
100 networking.firewall.enable = false;
101 time.timeZone = "Europe/London";
102 services.getty.autologinUser = "root";
103 environment.systemPackages = with pkgs; [curl vim git sqlite litecli postgresql_14];
104 services.tangled.knot = {
105 enable = true;
106 motd = "Welcome to the development knot!\n";
107 server = {
108 owner = envVar "TANGLED_VM_KNOT_OWNER";
109 hostname = envVarOr "TANGLED_VM_KNOT_HOST" "localhost:6444";
110 plcUrl = plcUrl;
111 jetstreamEndpoint = jetstream;
112 listenAddr = "0.0.0.0:6444";
113 dev = true;
114 };
115 knotmirrors = [
116 "http://localhost:7000"
117 ];
118 };
119 services.tangled.spindle = {
120 enable = true;
121 server = {
122 owner = envVar "TANGLED_VM_SPINDLE_OWNER";
123 hostname = envVarOr "TANGLED_VM_SPINDLE_HOST" "localhost:6555";
124 plcUrl = plcUrl;
125 jetstreamEndpoint = jetstream;
126 listenAddr = "0.0.0.0:6555";
127 dev = true;
128 queueSize = 100;
129 maxJobCount = 2;
130 secrets = {
131 provider = "sqlite";
132 };
133 };
134 };
135 services.postgresql = {
136 enable = true;
137 package = pkgs.postgresql_14;
138 ensureDatabases = ["mirror" "tap"];
139 ensureUsers = [
140 {name = "tnglr";}
141 ];
142 authentication = ''
143 local all tnglr trust
144 host all tnglr 127.0.0.1/32 trust
145 '';
146 };
147 services.tangled.knotmirror = {
148 enable = true;
149 listenAddr = "0.0.0.0:7000";
150 adminListenAddr = "0.0.0.0:7200";
151 hostname = "localhost:7000";
152 dbUrl = "postgresql://tnglr@127.0.0.1:5432/mirror";
153 fullNetwork = false;
154 tap.dbUrl = "postgresql://tnglr@127.0.0.1:5432/tap";
155 };
156 users = {
157 # So we don't have to deal with permission clashing between
158 # blank disk VMs and existing state
159 users.${config.services.tangled.knot.gitUser}.uid = 666;
160 groups.${config.services.tangled.knot.gitUser}.gid = 666;
161
162 # TODO: separate spindle user
163 };
164 systemd.services = let
165 mkDataSyncScripts = source: target: {
166 enableStrictShellChecks = true;
167
168 preStart = lib.mkBefore ''
169 mkdir -p ${target}
170 ${lib.getExe pkgs.rsync} -a ${source}/ ${target}
171 '';
172
173 postStop = lib.mkAfter ''
174 ${lib.getExe pkgs.rsync} -a ${target}/ ${source}
175 '';
176
177 serviceConfig.PermissionsStartOnly = true;
178 };
179 in {
180 knot = mkDataSyncScripts "/mnt/knot-data" config.services.tangled.knot.stateDir;
181 spindle = mkDataSyncScripts "/mnt/spindle-data" (builtins.dirOf config.services.tangled.spindle.server.dbPath);
182 knotmirror.after = ["postgresql.target"];
183 tap-knotmirror.after = ["postgresql.target"];
184 };
185 })
186 ];
187 }