this repo has no description
diogocastro.net
1flake_var := env_var_or_default("FLAKE", "")
2flake := if flake_var =~ '^\.*$' { justfile_directory() } else { flake_var }
3rebuild := if os() == "macos" { "sudo darwin-rebuild" } else { "nixos-rebuild" }
4system-args := if os() != "macos" { "--sudo --no-reexec" } else { "" }
5
6[private]
7default:
8 @just --list --unsorted
9
10[group('rebuild')]
11[private]
12builder goal *args:
13 {{ rebuild }} {{ goal }} \
14 --flake {{ flake }} \
15 {{ system-args }} \
16 {{ args }}
17
18[group('rebuild')]
19switch *args: (builder "switch" args)
20
21[group('rebuild')]
22[macos]
23provision host:
24 sudo nix run nix-darwin/master -- switch --flake {{ flake }}#{{ host }}
25
26[group('rebuild')]
27deploy host *args: (builder "switch" "--build-host " + host "--target-host " + host "--use-substitutes " + args)
28
29[group('utils')]
30clean:
31 nix-collect-garbage --delete-older-than 7d
32 nix store optimise
33
34[group('utils')]
35rotate:
36 /usr/bin/find secrets/ -name "*.yaml" | xargs -I {} sops rotate -i {}
37 /usr/bin/find secrets/ -name "*.yaml" | xargs -I {} sops updatekeys -y {}
38
39[group('utils')]
40update:
41 nix flake update \
42 --commit-lock-file \
43 --commit-lockfile-summary "flake: update inputs" \
44 --flake {{ flake }}