# Suppress greeting
set fish_greeting

# Homebrew can be in different places
if test -d /opt/homebrew
    eval (/opt/homebrew/bin/brew shellenv)
else if test -f /usr/local/bin/brew
    eval (/usr/local/bin/brew shellenv)
else if test -f /home/linuxbrew/.linuxbrew/bin/brew
    eval (/home/linuxbrew/.linuxbrew/bin/brew shellenv)
end

# Add Deno
fish_add_path ~/.deno/bin
# And bun
fish_add_path ~/.bun/bin
# And Go
set -x GOPATH ~/.local/share/go
fish_add_path ~/.local/share/go/bin
# And rust
fish_add_path ~/.cargo/bin
# Add mise, if installed
command -qs mise; and mise activate fish | source
# Add the Google Cloud SDK, if installed
test -f ~/.local/google-cloud-sdk/path.fish.inc; and source ~/.local/google-cloud-sdk/path.fish.inc

# pnpm needs to be handled differently for macOS and Linux because why not
if uname -a | grep -q Darwin
    set -x PNPM_HOME "$HOME/Library/pnpm"
else
    set -x PNPM_HOME "$HOME/.local/share/pnpm"
end
fish_add_path "$PNPM_HOME"

# Fun interactive bits
if status is-interactive
    command -qs atuin; and atuin init fish | source
    command -qs zoxide; and zoxide init fish | source
end

# If we're in Termux, add the SSH agent
if uname -a | grep -q Android
    set -x SSH_AUTH_SOCK $PREFIX/var/run/ssh-agent.socket
    ssh-add
end

# General
set -x BAT_THEME "Monokai Extended Bright"
set -x COLORTERM truecolor
set -x EDITOR hx
set -x RIPGREP_CONFIG_PATH ~/.ripgreprc

# Machine-specific overrides
test -f ~/.config/fish/local.fish; and source ~/.config/fish/local.fish

# Aliases
source ~/.config/fish/conf.d/abbrs.fish

# Add my own executables
fish_add_path ~/.local/bin