besaid.zone
1{
2 nixpkgs,
3 system,
4 hostSystem,
5 self,
6}: let
7 envVar = name: let
8 var = builtins.getEnv name;
9 in
10 if var == ""
11 then throw "\$${name} must be defined, see docs/hacking.md for more details"
12 else var;
13 envVarOr = name: default: let
14 var = builtins.getEnv name;
15 in
16 if var != ""
17 then var
18 else default;
19
20 plcUrl = envVarOr "TANGLED_VM_PLC_URL" "https://plc.directory";
21 jetstream = envVarOr "TANGLED_VM_JETSTREAM_ENDPOINT" "wss://jetstream1.us-west.bsky.network/subscribe";
22 relayUrl = envVarOr "TANGLED_VM_RELAY_URL" "https://relay1.us-east.bsky.network";
23in
24 nixpkgs.lib.nixosSystem {
25 inherit system;
26 modules = [
27 self.nixosModules.knot
28 self.nixosModules.spindle
29 ({
30 lib,
31 config,
32 pkgs,
33 ...
34 }: {
35 virtualisation.vmVariant.virtualisation = {
36 host.pkgs = import nixpkgs {system = hostSystem;};
37
38 graphics = false;
39 memorySize = 2048;
40 diskSize = 10 * 1024;
41 cores = 2;
42 forwardPorts = [
43 # ssh
44 {
45 from = "host";
46 host.port = 2222;
47 guest.port = 22;
48 }
49 # knot
50 {
51 from = "host";
52 host.port = 6444;
53 guest.port = 6444;
54 }
55 # spindle
56 {
57 from = "host";
58 host.port = 6555;
59 guest.port = 6555;
60 }
61 ];
62 sharedDirectories = {
63 # We can't use the 9p mounts directly for most of these
64 # as SQLite is incompatible with them. So instead we
65 # mount the shared directories to a different location
66 # and copy the contents around on service start/stop.
67 knotData = {
68 source = "$TANGLED_VM_DATA_DIR/knot";
69 target = "/mnt/knot-data";
70 };
71 spindleData = {
72 source = "$TANGLED_VM_DATA_DIR/spindle";
73 target = "/mnt/spindle-data";
74 };
75 spindleLogs = {
76 source = "$TANGLED_VM_DATA_DIR/spindle-logs";
77 target = "/var/log/spindle";
78 };
79 };
80 };
81 # This is fine because any and all ports that are forwarded to host are explicitly marked above, we don't need a separate guest firewall
82 networking.firewall.enable = false;
83 time.timeZone = "Europe/London";
84 services.getty.autologinUser = "root";
85 environment.systemPackages = with pkgs; [curl vim git sqlite litecli];
86 services.tangled.knot = {
87 enable = true;
88 motd = "Welcome to the development knot!\n";
89 server = {
90 owner = envVar "TANGLED_VM_KNOT_OWNER";
91 hostname = envVarOr "TANGLED_VM_KNOT_HOST" "localhost:6444";
92 plcUrl = plcUrl;
93 jetstreamEndpoint = jetstream;
94 listenAddr = "0.0.0.0:6444";
95 };
96 };
97 services.tangled.spindle = {
98 enable = true;
99 atpRelayUrl = relayUrl;
100 server = {
101 owner = envVar "TANGLED_VM_SPINDLE_OWNER";
102 hostname = envVarOr "TANGLED_VM_SPINDLE_HOST" "localhost:6555";
103 plcUrl = plcUrl;
104 jetstreamEndpoint = jetstream;
105 listenAddr = "0.0.0.0:6555";
106 dev = true;
107 queueSize = 100;
108 maxJobCount = 2;
109 secrets = {
110 provider = "sqlite";
111 };
112 };
113 };
114 users = {
115 # So we don't have to deal with permission clashing between
116 # blank disk VMs and existing state
117 users.${config.services.tangled.knot.gitUser}.uid = 666;
118 groups.${config.services.tangled.knot.gitUser}.gid = 666;
119
120 # TODO: separate spindle user
121 };
122 systemd.services = let
123 mkDataSyncScripts = source: target: {
124 enableStrictShellChecks = true;
125
126 preStart = lib.mkBefore ''
127 mkdir -p ${target}
128 ${lib.getExe pkgs.rsync} -a ${source}/ ${target}
129 '';
130
131 postStop = lib.mkAfter ''
132 ${lib.getExe pkgs.rsync} -a ${target}/ ${source}
133 '';
134
135 serviceConfig.PermissionsStartOnly = true;
136 };
137 in {
138 knot = mkDataSyncScripts "/mnt/knot-data" config.services.tangled.knot.stateDir;
139 spindle = mkDataSyncScripts "/mnt/spindle-data" (builtins.dirOf config.services.tangled.spindle.server.dbPath);
140 };
141 })
142 ];
143 }