besaid.zone
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 gitignore = {
27 url = "github:hercules-ci/gitignore.nix";
28 inputs.nixpkgs.follows = "nixpkgs";
29 };
30 };
31
32 outputs = {
33 self,
34 nixpkgs,
35 indigo,
36 htmx-src,
37 lucide-src,
38 gitignore,
39 inter-fonts-src,
40 ibm-plex-mono-src,
41 }: let
42 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
43 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
44 nixpkgsFor = forAllSystems (system:
45 import nixpkgs {
46 inherit system;
47 overlays = [self.overlays.default];
48 });
49 inherit (gitignore.lib) gitignoreSource;
50 in {
51 overlays.default = final: prev: let
52 goModHash = "sha256-ZckpIPqFk7/XBiEJUbmrAzdjAxV62hv896xqAXF2aZs=";
53 appviewBuildAttrs = final:
54 with final; {
55 pname = "appview";
56 version = "0.1.0";
57 src = gitignoreSource ./.;
58 postUnpack = ''
59 pushd source
60 mkdir -p appview/pages/static/{fonts,icons}
61 cp -f ${htmx-src} appview/pages/static/htmx.min.js
62 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
63 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
64 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
65 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
66 ${pkgs.tailwindcss}/bin/tailwindcss -i input.css -o appview/pages/static/tw.css
67 popd
68 '';
69 doCheck = false;
70 subPackages = ["cmd/appview"];
71 vendorHash = goModHash;
72 env.CGO_ENABLED = 1;
73 stdenv = pkgsStatic.stdenv;
74 };
75 knotBuildAttrs = final:
76 with final; {
77 pname = "knot";
78 version = "0.1.0";
79 src = gitignoreSource ./.;
80 subPackages = ["cmd/knot"];
81 vendorHash = goModHash;
82 env.CGO_ENABLED = 1;
83 };
84 in {
85 indigo-lexgen = final.buildGoModule {
86 pname = "indigo-lexgen";
87 version = "0.1.0";
88 src = indigo;
89 subPackages = ["cmd/lexgen"];
90 vendorHash = "sha256-pGc29fgJFq8LP7n/pY1cv6ExZl88PAeFqIbFEhB3xXs=";
91 doCheck = false;
92 };
93
94 # appview packages
95 appview = final.pkgsStatic.buildGoModule (appviewBuildAttrs final);
96 appview-cross = final.pkgsCross.gnu64.pkgsStatic.buildGoModule (appviewBuildAttrs final);
97
98 # knot packages
99 knot = with final;
100 final.pkgsStatic.buildGoModule ((knotBuildAttrs final)
101 // {
102 nativeBuildInputs = [final.makeWrapper];
103 installPhase = ''
104 runHook preInstall
105
106 mkdir -p $out/bin
107 cp $GOPATH/bin/knot $out/bin/knot
108
109 wrapProgram $out/bin/knot \
110 --prefix PATH : ${pkgs.git}/bin
111
112 runHook postInstall
113 '';
114 });
115 knot-cross = final.pkgsCross.gnu64.pkgsStatic.buildGoModule (knotBuildAttrs final); # cross-compile on darwin to x86_64-linux
116 knot-unwrapped = final.pkgsStatic.buildGoModule (knotBuildAttrs final);
117
118 genjwks = final.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
119 };
120 packages = forAllSystems (system: {
121 inherit
122 (nixpkgsFor."${system}")
123 indigo-lexgen
124 appview
125 appview-cross
126 knot
127 knot-cross
128 knot-unwrapped
129 genjwks
130 ;
131 });
132 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
133 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
134 devShells = forAllSystems (system: let
135 pkgs = nixpkgsFor.${system};
136 staticShell = pkgs.mkShell.override {
137 stdenv = pkgs.pkgsStatic.stdenv;
138 };
139 in {
140 default = staticShell {
141 nativeBuildInputs = [
142 pkgs.go
143 pkgs.air
144 pkgs.gopls
145 pkgs.httpie
146 pkgs.indigo-lexgen
147 pkgs.litecli
148 pkgs.websocat
149 pkgs.tailwindcss
150 pkgs.nixos-shell
151 pkgs.redis
152 ];
153 shellHook = ''
154 mkdir -p appview/pages/static/{fonts,icons}
155 cp -f ${htmx-src} appview/pages/static/htmx.min.js
156 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
157 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
158 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
159 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
160 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
161 '';
162 env.CGO_ENABLED = 1;
163 };
164 });
165 apps = forAllSystems (system: let
166 pkgs = nixpkgsFor."${system}";
167 air-watcher = name: arg:
168 pkgs.writeShellScriptBin "run"
169 ''
170 ${pkgs.air}/bin/air -c /dev/null \
171 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
172 -build.bin "./out/${name}.out ${arg}" \
173 -build.stop_on_error "true" \
174 -build.include_ext "go"
175 '';
176 tailwind-watcher =
177 pkgs.writeShellScriptBin "run"
178 ''
179 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
180 '';
181 in {
182 watch-appview = {
183 type = "app";
184 program = ''${air-watcher "appview" ""}/bin/run'';
185 };
186 watch-knot = {
187 type = "app";
188 program = ''${air-watcher "knot" "server"}/bin/run'';
189 };
190 watch-tailwind = {
191 type = "app";
192 program = ''${tailwind-watcher}/bin/run'';
193 };
194 });
195
196 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
197 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
198 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
199 };
200}