besaid.zone
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 sqlite-lib-src = {
27 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
28 flake = false;
29 };
30 gitignore = {
31 url = "github:hercules-ci/gitignore.nix";
32 inputs.nixpkgs.follows = "nixpkgs";
33 };
34 };
35
36 outputs = {
37 self,
38 nixpkgs,
39 indigo,
40 htmx-src,
41 lucide-src,
42 gitignore,
43 inter-fonts-src,
44 sqlite-lib-src,
45 ibm-plex-mono-src,
46 }: let
47 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
48 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
49 nixpkgsFor = forAllSystems (system:
50 import nixpkgs {
51 inherit system;
52 overlays = [self.overlays.default];
53 });
54 inherit (gitignore.lib) gitignoreSource;
55 in {
56 overlays.default = final: prev: let
57 goModHash = "sha256-ZckpIPqFk7/XBiEJUbmrAzdjAxV62hv896xqAXF2aZs=";
58 knotBuildAttrs = final:
59 with final; {
60 pname = "knot";
61 version = "0.1.0";
62 src = gitignoreSource ./.;
63 subPackages = ["cmd/knot"];
64 vendorHash = goModHash;
65 env.CGO_ENABLED = 1;
66 };
67 appviewDeps = {
68 inherit htmx-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
69 };
70 in {
71 lexgen = final.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
72 appview = final.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
73 appview-cross = final.pkgsCross.gnu64.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
74 sqlite-lib = final.pkgsStatic.callPackage ./nix/pkgs/sqlite-lib.nix {
75 inherit (final.pkgsStatic) gcc;
76 inherit sqlite-lib-src;
77 };
78
79 # knot packages
80 knot = with final;
81 final.pkgsStatic.buildGoModule ((knotBuildAttrs final)
82 // {
83 nativeBuildInputs = [final.makeWrapper];
84 installPhase = ''
85 runHook preInstall
86
87 mkdir -p $out/bin
88 cp $GOPATH/bin/knot $out/bin/knot
89
90 wrapProgram $out/bin/knot \
91 --prefix PATH : ${pkgs.git}/bin
92
93 runHook postInstall
94 '';
95 });
96 knot-cross = final.pkgsCross.gnu64.pkgsStatic.buildGoModule (knotBuildAttrs final); # cross-compile on darwin to x86_64-linux
97 knot-unwrapped = final.pkgsStatic.buildGoModule (knotBuildAttrs final);
98
99 genjwks = final.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
100 };
101
102 packages = forAllSystems (system: {
103 inherit
104 (nixpkgsFor."${system}")
105 lexgen
106 appview
107 appview-cross
108 knot
109 knot-cross
110 knot-unwrapped
111 genjwks
112 sqlite-lib
113 ;
114 });
115 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
116 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
117 devShells = forAllSystems (system: let
118 pkgs = nixpkgsFor.${system};
119 staticShell = pkgs.mkShell.override {
120 stdenv = pkgs.pkgsStatic.stdenv;
121 };
122 in {
123 default = staticShell {
124 nativeBuildInputs = [
125 pkgs.go
126 pkgs.air
127 pkgs.gopls
128 pkgs.httpie
129 pkgs.lexgen
130 pkgs.litecli
131 pkgs.websocat
132 pkgs.tailwindcss
133 pkgs.nixos-shell
134 pkgs.redis
135 ];
136 shellHook = ''
137 mkdir -p appview/pages/static/{fonts,icons}
138 cp -f ${htmx-src} appview/pages/static/htmx.min.js
139 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
140 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
141 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
142 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
143 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
144 '';
145 env.CGO_ENABLED = 1;
146 };
147 });
148 apps = forAllSystems (system: let
149 pkgs = nixpkgsFor."${system}";
150 air-watcher = name: arg:
151 pkgs.writeShellScriptBin "run"
152 ''
153 ${pkgs.air}/bin/air -c /dev/null \
154 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
155 -build.bin "./out/${name}.out ${arg}" \
156 -build.stop_on_error "true" \
157 -build.include_ext "go"
158 '';
159 tailwind-watcher =
160 pkgs.writeShellScriptBin "run"
161 ''
162 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
163 '';
164 in {
165 watch-appview = {
166 type = "app";
167 program = ''${air-watcher "appview" ""}/bin/run'';
168 };
169 watch-knot = {
170 type = "app";
171 program = ''${air-watcher "knot" "server"}/bin/run'';
172 };
173 watch-tailwind = {
174 type = "app";
175 program = ''${tailwind-watcher}/bin/run'';
176 };
177 });
178
179 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
180 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
181 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
182 };
183}