set shell := ["bash", "-cu"]

APP_DIR := "app"
SERVER_DIR := "server"

alias srv := server
alias s := server
alias a := app

default:
	@just --list

server:
	cd "{{SERVER_DIR}}" && cargo run

app:
	cd "{{APP_DIR}}" && WEBKIT_DISABLE_DMABUF_RENDERER=1 bun run tauri dev

vite:
	cd "{{APP_DIR}}" && bun run vite

duo:
  #!/usr/bin/env bash
  set -euo pipefail

  VITE_HOST="127.0.0.1"
  VITE_PORT="5173"

  mkdir -p /tmp/ppA /tmp/ppB

  VITE_PID=""
  TAURI_A_PID=""
  TAURI_B_PID=""

  cleanup() {
    for pid in "$TAURI_A_PID" "$TAURI_B_PID" "$VITE_PID"; do
      [[ -n "$pid" ]] && kill "$pid" 2>/dev/null || true
    done
  }
  trap cleanup INT TERM EXIT

  # Start Vite
  (cd app && bun run vite) &
  VITE_PID=$!

  # Start Tauri instance A
  (cd app/src-tauri && \
    WEBKIT_DISABLE_DMABUF_RENDERER=1 \
    XDG_DATA_HOME=/tmp/ppA \
    cargo run) &
  TAURI_A_PID=$!

  # Start Tauri instance B
  (cd app/src-tauri && \
    WEBKIT_DISABLE_DMABUF_RENDERER=1 \
    XDG_DATA_HOME=/tmp/ppB \
    cargo run) &
  TAURI_B_PID=$!

  wait