aria.rip
this repo has no description
1candelabra := `which candelabra-cli 2>/dev/null || echo ./target/debug/candelabra-cli`
2target_dir := justfile_directory() / "target"
3tests_dir := justfile_directory() / "tests"
4tests_manifest := tests_dir / "Cargo.toml"
5
6export RUST_LOG := "debug"
7
8cost-models: rebuild
9 rm -fr {{target_dir}}/candelabra
10 @IMPLS=`{{candelabra}} list-library 2>&1 | cut -d ']' -f 2 | grep ::`; for impl in $IMPLS; do just cost-model $impl; done
11
12selections *SELECTFLAGS: rebuild
13 @cd tests/ && for i in $(ls -d */); do [ "${i%%/}" == "target" ] || just select ${i%%/} {{SELECTFLAGS}}; done
14
15rebuild:
16 which candelabra-cli 2>/dev/null || cargo build
17 echo "Candelabra Path: {{candelabra}}"
18
19cost-model impl: (section-start ("cost-model-" + impl)) && (section-end ("cost-model-" + impl))
20 {{candelabra}} -l cost-model {{impl}}
21
22select proj *FLAGS: (section-start ("compare-" + proj)) && (section-end ("compare-" + proj))
23 {{candelabra}} -l --manifest-path {{tests_manifest}} -p {{proj}} select {{FLAGS}}
24
25profile proj *FLAGS:
26 {{candelabra}} --manifest-path {{tests_manifest}} -p {{proj}} select {{FLAGS}}
27
28@section-start NAME:
29 echo -e "\e[0Ksection_start:`date +%s`:{{replace(NAME, ":", "-")}}\r\e[0K{{replace(NAME, ":", "-")}}"
30
31@section-end NAME:
32 echo -e "\e[0Ksection_end:`date +%s`:{{replace(NAME, ":", "-")}}\r\e[0K"